SConscript revision 8887 
1# -*- mode:python -*-
2
3# Copyright (c) 2006 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28#
29# Authors: Steve Reinhardt
30
31import sys
32
33Import('*')
34
35#################################################################
36#
37# ISA "switch header" generation.
38#
39# Auto-generate arch headers that include the right ISA-specific
40# header based on the setting of THE_ISA preprocessor variable.
41#
42#################################################################
43
44# List of headers to generate
45isa_switch_hdrs = Split('''
46        interrupts.hh
47        isa.hh
48        isa_traits.hh
49        kernel_stats.hh
50        locked_mem.hh
51        microcode_rom.hh
52        mmapped_ipr.hh
53        mt.hh
54        process.hh
55        predecoder.hh
56        registers.hh
57        remote_gdb.hh
58        stacktrace.hh
59        tlb.hh
60        types.hh
61        utility.hh
62        vtophys.hh
63        ''')
64
65# Set up this directory to support switching headers
66make_switching_dir('arch', isa_switch_hdrs, env)
67
68#################################################################
69#
70# Include architecture-specific files.
71#
72#################################################################
73
74#
75# Build a SCons scanner for ISA files
76#
77import SCons.Scanner
78
79isa_scanner = SCons.Scanner.Classic("ISAScan",
80                                    [".isa", ".ISA"],
81                                    "SRCDIR",
82                                    r'^\s*##include\s+"([\w/.-]*)"')
83
84env.Append(SCANNERS = isa_scanner)
85
86#
87# Now create a Builder object that uses isa_parser.py to generate C++
88# output from the ISA description (*.isa) files.
89#
90
91isa_parser = File('isa_parser.py')
92
93# The emitter patches up the sources & targets to include the
94# autogenerated files as targets and isa parser itself as a source.
95def isa_desc_emitter(target, source, env):
96    cpu_models = list(env['CPU_MODELS'])
97    cpu_models.append('CheckerCPU')
98
99    # Several files are generated from the ISA description.
100    # We always get the basic decoder and header file.
101    target = [ 'decoder.cc', 'decoder.hh', 'max_inst_regs.hh' ]
102    # We also get an execute file for each selected CPU model.
103    target += [CpuModel.dict[cpu].filename for cpu in cpu_models]
104
105    # List the isa parser as a source.
106    source += [ isa_parser ]
107    # Add in the CPU models.
108    source += [ Value(m) for m in cpu_models ]
109
110    return target, source
111
112ARCH_DIR = Dir('.')
113
114# import ply here because SCons screws with sys.path when performing actions.
115import ply
116
117def isa_desc_action_func(target, source, env):
118    # Add the current directory to the system path so we can import files
119    sys.path[0:0] = [ ARCH_DIR.srcnode().abspath ]
120    import isa_parser
121
122    # Skip over the ISA description itself and the parser to the CPU models.
123    models = [ s.get_contents() for s in source[2:] ]
124    cpu_models = [CpuModel.dict[cpu] for cpu in models]
125    parser = isa_parser.ISAParser(target[0].dir.abspath, cpu_models)
126    parser.parse_isa_desc(source[0].abspath)
127isa_desc_action = MakeAction(isa_desc_action_func, Transform("ISA DESC", 1))
128
129# Also include the CheckerCPU as one of the models if it is being
130# enabled via command line.
131isa_desc_builder = Builder(action=isa_desc_action, emitter=isa_desc_emitter)
132
133env.Append(BUILDERS = { 'ISADesc' : isa_desc_builder })
134
135DebugFlag('IntRegs')
136DebugFlag('FloatRegs')
137DebugFlag('MiscRegs')
138CompoundFlag('Registers', [ 'IntRegs', 'FloatRegs', 'MiscRegs' ])
139