SConscript revision 2637:18e4273315cd 
1# -*- mode:python -*-
2
3# Copyright (c) 2006 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29import os.path
30
31# Import build environment variable from SConstruct.
32Import('env')
33
34# Right now there are no source files immediately in this directory
35sources = []
36
37#################################################################
38#
39# ISA "switch header" generation.
40#
41# Auto-generate arch headers that include the right ISA-specific
42# header based on the setting of THE_ISA preprocessor variable.
43#
44#################################################################
45
46# List of headers to generate
47isa_switch_hdrs = Split('''
48	arguments.hh
49	constants.hh
50	faults.hh
51	isa_traits.hh
52	process.hh
53	regfile.hh
54	stacktrace.hh
55	tlb.hh
56	types.hh
57	utility.hh
58	vtophys.hh
59        ''')
60
61# Generate the header.  target[0] is the full path of the output
62# header to generate.  'source' is a dummy variable, since we get the
63# list of ISAs from env['ALL_ISA_LIST'].
64def gen_switch_hdr(target, source, env):
65    fname = str(target[0])
66    basename = os.path.basename(fname)
67    f = open(fname, 'w')
68    f.write('#include "arch/isa_specific.hh"\n')
69    cond = '#if'
70    for isa in env['ALL_ISA_LIST']:
71        f.write('%s THE_ISA == %s_ISA\n#include "arch/%s/%s"\n'
72                % (cond, isa.upper(), isa, basename))
73        cond = '#elif'
74    f.write('#else\n#error "THE_ISA not set"\n#endif\n')
75    f.close()
76    return 0
77
78# String to print when generating header
79def gen_switch_hdr_string(target, source, env):
80    return "Generating ISA switch header " + str(target[0])
81
82# Build SCons Action object. 'varlist' specifies env vars that this
83# action depends on; when env['ALL_ISA_LIST'] changes these actions
84# should get re-executed.
85switch_hdr_action = Action(gen_switch_hdr, gen_switch_hdr_string,
86                           varlist=['ALL_ISA_LIST'])
87
88# Instantiate actions for each header
89for hdr in isa_switch_hdrs:
90    env.Command(hdr, [], switch_hdr_action)
91
92#################################################################
93#
94# Include architecture-specific files.
95#
96#################################################################
97
98#
99# Build a SCons scanner for ISA files
100#
101import SCons.Scanner
102
103isa_scanner = SCons.Scanner.Classic("ISAScan",
104                                    [".isa", ".ISA"],
105                                    "SRCDIR",
106                                    r'^\s*##include\s+"([\w/.-]*)"')
107
108env.Append(SCANNERS = isa_scanner)
109
110#
111# Now create a Builder object that uses isa_parser.py to generate C++
112# output from the ISA description (*.isa) files.
113#
114
115# Convert to File node to fix path
116isa_parser = File('isa_parser.py')
117cpu_models_file = File('../cpu/cpu_models.py')
118
119# This sucks in the defintions of the CpuModel objects.
120execfile(cpu_models_file.srcnode().abspath)
121
122# Several files are generated from the ISA description.
123# We always get the basic decoder and header file.
124isa_desc_gen_files = Split('decoder.cc decoder.hh')
125# We also get an execute file for each selected CPU model.
126isa_desc_gen_files += [CpuModel.dict[cpu].filename
127                       for cpu in env['CPU_MODELS']]
128
129# The emitter patches up the sources & targets to include the
130# autogenerated files as targets and isa parser itself as a source.
131def isa_desc_emitter(target, source, env):
132    return (isa_desc_gen_files, [isa_parser, cpu_models_file] + source)
133
134# Pieces are in place, so create the builder.
135isa_desc_builder = Builder(action='python2.4 $SOURCES $TARGET.dir $CPU_MODELS',
136                           emitter = isa_desc_emitter)
137
138env.Append(BUILDERS = { 'ISADesc' : isa_desc_builder })
139
140#
141# Now include other ISA-specific sources from the ISA subdirectories.
142#
143
144isa = env['TARGET_ISA'] # someday this may be a list of ISAs
145
146# Let the target architecture define what additional sources it needs
147sources += SConscript(os.path.join(isa, 'SConscript'),
148                      exports = 'env', duplicate = False)
149
150Return('sources')
151