SConscript revision 2655 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29import os, os.path, re, sys
30from zipfile import PyZipFile
31
32# handy function for path joins
33def join(*args):
34    return os.path.normpath(os.path.join(*args))
35
36Import('env')
37
38# This SConscript is in charge of collecting .py files and generating a zip archive that is appended to the m5 binary.
39
40# Copy .py source files here (relative to src/python in the build
41# directory).
42pyzip_root = 'zip'
43
44# List of files & directories to include in the zip file.  To include
45# a package, list only the root directory of the package, not any
46# internal .py files (else they will get the path stripped off when
47# they are imported into the zip file).
48pyzip_files = []
49
50# List of additional files on which the zip archive depends, but which
51# are not included in pyzip_files... i.e. individual .py files within
52# a package.
53pyzip_dep_files = []
54
55# Add the specified package to the zip archive.  Adds the directory to
56# pyzip_files and all included .py files to pyzip_dep_files.
57def addPkg(pkgdir):
58    pyzip_files.append(join(pyzip_root, pkgdir))
59    origdir = os.getcwd()
60    srcdir = join(Dir('.').srcnode().abspath, pkgdir)
61    os.chdir(srcdir)
62    for path, dirs, files in os.walk('.'):
63        for i,dir in enumerate(dirs):
64            if dir == 'SCCS':
65                del dirs[i]
66                break
67
68        for f in files:
69            if f.endswith('.py'):
70                source = join(pkgdir, path, f)
71                target = join(pyzip_root, source)
72                pyzip_dep_files.append(target)
73                env.CopyFile(target, source)
74
75    os.chdir(origdir)
76
77# Generate Python file that contains a dict specifying the current
78# build_env flags.
79def MakeDefinesPyFile(target, source, env):
80    f = file(str(target[0]), 'w')
81    print >>f, "import __main__"
82    print >>f, "__main__.m5_build_env = ",
83    print >>f, source[0]
84    f.close()
85
86optionDict = dict([(opt, env[opt]) for opt in env.ExportOptions])
87env.Command('defines.py', Value(optionDict), MakeDefinesPyFile)
88
89# Now specify the packages & files for the zip archive.
90addPkg('m5')
91pyzip_files.append('defines.py')
92pyzip_files.append(join(env['ROOT'], 'util/pbs/jobfile.py'))
93
94# Action function to build the zip archive.  Uses the PyZipFile module
95# included in the standard Python library.
96def buildPyZip(target, source, env):
97    pzf = PyZipFile(str(target[0]), 'w')
98    for s in source:
99        pzf.writepy(str(s))
100
101# Add the zip file target to the environment.
102env.Command('m5py.zip', pyzip_files, buildPyZip)
103env.Depends('m5py.zip', pyzip_dep_files)
104