SConscript revision 8881:042d509574c1 
1# -*- mode:python -*-
2
3# Copyright (c) 2009 The Hewlett-Packard Development Company
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28#
29# Authors: Nathan Binkert
30
31import os
32import re
33import sys
34
35from os.path import isdir, isfile, join as joinpath
36
37from SCons.Scanner import Classic
38
39Import('*')
40
41if env['PROTOCOL'] == 'None':
42    Return()
43
44protocol_dir = Dir('.')
45html_dir = Dir('html')
46slicc_dir = Dir('../slicc')
47
48sys.path[1:1] = [ Dir('..').srcnode().abspath ]
49from slicc.parser import SLICC
50
51slicc_depends = []
52for root,dirs,files in os.walk(slicc_dir.srcnode().abspath):
53    for f in files:
54        if f.endswith('.py'):
55            slicc_depends.append(File(joinpath(root, f)))
56
57#
58# Use SLICC
59#
60env['SLICC_PATH'] = str(protocol_dir)
61slicc_scanner = Classic("SliccScanner", ['.sm', '.slicc'], "SLICC_PATH",
62                        r'''include[ \t]["'](.*)["'];''')
63env.Append(SCANNERS=slicc_scanner)
64
65def slicc_emitter(target, source, env):
66    assert len(source) == 1
67    filepath = source[0].srcnode().abspath
68
69    slicc = SLICC(filepath, verbose=False)
70    slicc.process()
71    slicc.writeCodeFiles(protocol_dir.abspath)
72    if env['SLICC_HTML']:
73        slicc.writeHTMLFiles(html_dir.abspath)
74
75    target.extend([protocol_dir.File(f) for f in sorted(slicc.files())])
76    return target, source
77
78def slicc_action(target, source, env):
79    assert len(source) == 1
80    filepath = source[0].srcnode().abspath
81
82    slicc = SLICC(filepath, verbose=True)
83    slicc.process()
84    slicc.writeCodeFiles(protocol_dir.abspath)
85    if env['SLICC_HTML']:
86        slicc.writeHTMLFiles(html_dir.abspath)
87
88slicc_builder = Builder(action=MakeAction(slicc_action, Transform("SLICC")),
89                        emitter=slicc_emitter)
90
91protocol = env['PROTOCOL']
92sources = [ protocol_dir.File("%s.slicc" % protocol) ]
93
94env.Append(BUILDERS={'SLICC' : slicc_builder})
95nodes = env.SLICC([], sources)
96env.Depends(nodes, slicc_depends)
97
98for f in nodes:
99    s = str(f)
100    if s.endswith('.cc'):
101        Source(f)
102    elif s.endswith('.py'):
103        SimObject(f)
104
105