SConscript revision 2504 
1# -*- mode:python -*-
2
3# Copyright (c) 2006 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29import os
30import os.path
31
32# Import build environment variable from SConstruct.
33Import('env')
34
35#################################################################
36#
37# Generate StaticInst execute() method signatures.
38#
39# There must be one signature for each CPU model compiled in.
40# Since the set of compiled-in models is flexible, we generate a
41# header containing the appropriate set of signatures on the fly.
42#
43#################################################################
44
45# CPU model-specific data is contained in cpu_models.py
46# Convert to SCons File node to get path handling
47models_db = File('cpu_models.py')
48# slurp in contents of file
49execfile(models_db.srcnode().abspath)
50
51# Template for execute() signature.
52exec_sig_template = '''
53virtual Fault execute(%s *xc, Trace::InstRecord *traceData) const = 0;
54'''
55
56# Generate header.  
57def gen_cpu_exec_signatures(target, source, env):
58    f = open(str(target[0]), 'w')
59    print >> f, '''
60#ifndef __CPU_STATIC_INST_EXEC_SIGS_HH__
61#define __CPU_STATIC_INST_EXEC_SIGS_HH__
62'''
63    for cpu in env['CPU_MODELS']:
64        xc_type = CpuModel.dict[cpu].strings['CPU_exec_context']
65        print >> f, exec_sig_template % xc_type
66    print >> f, '''
67#endif  // __CPU_STATIC_INST_EXEC_SIGS_HH__
68'''
69
70# Generate string that gets printed when header is rebuilt
71def gen_sigs_string(target, source, env):
72    return "Generating static_inst_exec_sigs.hh: " \
73           + ', '.join(env['CPU_MODELS'])
74
75# Add command to generate header to environment.
76env.Command('static_inst_exec_sigs.hh', models_db,
77            Action(gen_cpu_exec_signatures, gen_sigs_string,
78                   varlist = ['CPU_MODELS']))
79
80#################################################################
81#
82# Include CPU-model-specific files based on set of models
83# specified in CPU_MODELS build option.
84#
85#################################################################
86
87sources = []
88
89if 'SimpleCPU' in env['CPU_MODELS']:
90    sources += Split('simple/cpu.cc')
91
92if 'FastCPU' in env['CPU_MODELS']:
93    sources += Split('fast/cpu.cc')
94
95if 'AlphaFullCPU' in env['CPU_MODELS']:
96    sources += Split('''
97        o3/2bit_local_pred.cc
98        o3/alpha_dyn_inst.cc
99        o3/alpha_cpu.cc
100        o3/alpha_cpu_builder.cc
101        o3/bpred_unit.cc
102        o3/btb.cc
103        o3/commit.cc
104        o3/decode.cc
105        o3/fetch.cc
106        o3/free_list.cc
107        o3/cpu.cc
108        o3/iew.cc
109        o3/inst_queue.cc
110        o3/ldstq.cc
111        o3/mem_dep_unit.cc
112        o3/ras.cc
113        o3/rename.cc
114        o3/rename_map.cc
115        o3/rob.cc
116        o3/sat_counter.cc
117        o3/store_set.cc
118        o3/tournament_pred.cc
119        ''')
120
121# FullCPU sources are included from m5/SConscript since they're not
122# below this point in the file hierarchy.
123
124# Convert file names to SCons File objects.  This takes care of the
125# path relative to the top of the directory tree.
126sources = [File(s) for s in sources]
127
128Return('sources')
129
130