SConscript revision 3719:23ca579a363a 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28#
29# Authors: Steve Reinhardt
30
31import os
32import sys
33from os.path import isfile, join as joinpath
34
35# This file defines how to build a particular configuration of M5
36# based on variable settings in the 'env' build environment.
37
38# Import build environment variable from SConstruct.
39Import('env')
40
41###################################################
42#
43# Define needed sources.
44#
45###################################################
46
47# Base sources used by all configurations.
48
49base_sources = Split('''
50	base/annotate.cc
51	base/circlebuf.cc
52	base/cprintf.cc
53	base/fast_alloc.cc
54	base/fifo_buffer.cc
55	base/hostinfo.cc
56	base/hybrid_pred.cc
57	base/inifile.cc
58	base/intmath.cc
59	base/match.cc
60	base/misc.cc
61	base/output.cc
62	base/pollevent.cc
63	base/range.cc
64	base/random.cc
65	base/sat_counter.cc
66	base/socket.cc
67	base/statistics.cc
68	base/str.cc
69	base/time.cc
70	base/trace.cc
71	base/traceflags.cc
72	base/userinfo.cc
73	base/compression/lzss_compression.cc
74	base/loader/aout_object.cc
75	base/loader/ecoff_object.cc
76	base/loader/elf_object.cc
77	base/loader/raw_object.cc
78	base/loader/object_file.cc
79	base/loader/symtab.cc
80	base/stats/events.cc
81	base/stats/statdb.cc
82	base/stats/visit.cc
83	base/stats/text.cc
84
85        cpu/activity.cc
86	cpu/base.cc
87	cpu/cpuevent.cc
88	cpu/exetrace.cc
89        cpu/func_unit.cc
90        cpu/op_class.cc
91	cpu/pc_event.cc
92        cpu/quiesce_event.cc
93	cpu/static_inst.cc
94        cpu/simple_thread.cc
95        cpu/thread_state.cc
96
97        mem/bridge.cc
98        mem/bus.cc
99        mem/dram.cc
100        mem/mem_object.cc
101        mem/packet.cc
102        mem/physical.cc
103        mem/port.cc
104        mem/tport.cc
105
106        mem/cache/base_cache.cc
107        mem/cache/cache.cc
108        mem/cache/coherence/coherence_protocol.cc
109        mem/cache/coherence/uni_coherence.cc
110        mem/cache/miss/blocking_buffer.cc
111        mem/cache/miss/miss_buffer.cc
112        mem/cache/miss/miss_queue.cc
113        mem/cache/miss/mshr.cc
114        mem/cache/miss/mshr_queue.cc
115        mem/cache/prefetch/base_prefetcher.cc
116        mem/cache/prefetch/ghb_prefetcher.cc
117        mem/cache/prefetch/prefetcher.cc
118        mem/cache/prefetch/stride_prefetcher.cc
119        mem/cache/prefetch/tagged_prefetcher.cc
120        mem/cache/tags/base_tags.cc
121        mem/cache/tags/cache_tags.cc
122        mem/cache/tags/fa_lru.cc
123        mem/cache/tags/iic.cc
124        mem/cache/tags/lru.cc
125        mem/cache/tags/repl/gen.cc
126        mem/cache/tags/repl/repl.cc
127        mem/cache/tags/split.cc
128        mem/cache/tags/split_lifo.cc
129        mem/cache/tags/split_lru.cc
130
131        mem/cache/cache_builder.cc
132
133        python/swig/debug_wrap.cc
134        python/swig/main_wrap.cc
135
136	sim/builder.cc
137	sim/debug.cc
138	sim/eventq.cc
139	sim/faults.cc
140	sim/main.cc
141	sim/param.cc
142	sim/root.cc
143	sim/serialize.cc
144	sim/sim_events.cc
145	sim/sim_object.cc
146	sim/startup.cc
147	sim/stat_context.cc
148	sim/stat_control.cc
149	sim/system.cc
150	sim/trace_context.cc
151        ''')
152
153trace_reader_sources = Split('''
154        cpu/trace/reader/mem_trace_reader.cc
155        cpu/trace/reader/ibm_reader.cc
156        cpu/trace/reader/itx_reader.cc
157        cpu/trace/reader/m5_reader.cc
158        cpu/trace/opt_cpu.cc
159        cpu/trace/trace_cpu.cc
160        ''')
161
162
163
164# MySql sources
165mysql_sources = Split('''
166	base/mysql.cc
167	base/stats/mysql.cc
168        ''')
169
170# Full-system sources
171full_system_sources = Split('''
172	base/crc.cc
173	base/inet.cc
174	base/remote_gdb.cc
175
176	cpu/intr_control.cc
177        cpu/profile.cc
178
179	dev/uart.cc
180	dev/uart8250.cc
181
182        mem/vport.cc
183
184	sim/pseudo_inst.cc
185        ''')
186	#dev/sinic.cc
187        #dev/i8254xGBe.cc
188
189if env['TARGET_ISA'] == 'alpha':
190    full_system_sources += Split('''
191	kern/tru64/dump_mbuf.cc
192	kern/tru64/printf.cc
193	kern/tru64/tru64_events.cc
194	kern/tru64/tru64_syscalls.cc
195        ''')
196
197# Syscall emulation (non-full-system) sources
198syscall_emulation_sources = Split('''
199        mem/translating_port.cc
200        mem/page_table.cc
201	sim/process.cc
202	sim/syscall_emul.cc
203        ''')
204
205#if env['TARGET_ISA'] == 'alpha':
206#    syscall_emulation_sources += Split('''
207#        kern/tru64/tru64.cc
208#        ''')
209
210memtest_sources = Split('''
211	cpu/memtest/memtest.cc
212        ''')
213
214# Include file paths are rooted in this directory.  SCons will
215# automatically expand '.' to refer to both the source directory and
216# the corresponding build directory to pick up generated include
217# files.
218env.Append(CPPPATH=Dir('.'))
219
220# Add a flag defining what THE_ISA should be for all compilation
221env.Append(CPPDEFINES=[('THE_ISA','%s_ISA' % env['TARGET_ISA'].upper())])
222
223arch_sources = SConscript(os.path.join('arch', 'SConscript'), exports = 'env')
224
225cpu_sources = SConscript(os.path.join('cpu', 'SConscript'), exports = 'env')
226
227if env['FULL_SYSTEM']:
228    dev_sources = SConscript(os.path.join('dev', 'SConscript'),
229                             exports = 'env')
230    full_system_sources += dev_sources
231
232    kern_sources = SConscript(os.path.join('kern', 'SConscript'),
233                              exports = 'env')
234    full_system_sources += kern_sources
235
236# Set up complete list of sources based on configuration.
237sources = base_sources + arch_sources + cpu_sources
238
239# encumbered should be last because we're adding to some of the other groups
240if isfile(joinpath(env['SRCDIR'], 'encumbered/SConscript')):
241    sources += SConscript('encumbered/SConscript', exports = 'env')
242
243
244if env['FULL_SYSTEM']:
245    sources += full_system_sources
246else:
247    sources += syscall_emulation_sources
248
249if env['USE_MYSQL']:
250    sources += mysql_sources
251
252for opt in env.ExportOptions:
253    env.ConfigFile(opt)
254
255###################################################
256#
257# Special build rules.
258#
259###################################################
260
261# base/traceflags.{cc,hh} are generated from base/traceflags.py.
262# $TARGET.base will expand to "<build-dir>/base/traceflags".
263env.Command(Split('base/traceflags.hh base/traceflags.cc'),
264            'base/traceflags.py',
265            'python $SOURCE $TARGET.base')
266
267SConscript('python/SConscript', exports = ['env'])
268
269# This function adds the specified sources to the given build
270# environment, and returns a list of all the corresponding SCons
271# Object nodes (including an extra one for date.cc).  We explicitly
272# add the Object nodes so we can set up special dependencies for
273# date.cc.
274def make_objs(sources, env):
275    objs = [env.Object(s) for s in sources]
276    # make date.cc depend on all other objects so it always gets
277    # recompiled whenever anything else does
278    date_obj = env.Object('base/date.cc')
279    env.Depends(date_obj, objs)
280    objs.append(date_obj)
281    return objs
282
283###################################################
284#
285# Define binaries.  Each different build type (debug, opt, etc.) gets
286# a slightly different build environment.
287#
288###################################################
289
290# List of constructed environments to pass back to SConstruct
291envList = []
292
293# Function to create a new build environment as clone of current
294# environment 'env' with modified object suffix and optional stripped
295# binary.  Additional keyword arguments are appended to corresponding
296# build environment vars.
297def makeEnv(label, objsfx, strip = False, **kwargs):
298    newEnv = env.Copy(OBJSUFFIX=objsfx)
299    newEnv.Label = label
300    newEnv.Append(**kwargs)
301    exe = 'm5.' + label  # final executable
302    bin = exe + '.bin'   # executable w/o appended Python zip archive
303    newEnv.Program(bin, make_objs(sources, newEnv))
304    if strip:
305        stripped_bin = bin + '.stripped'
306        newEnv.Command(stripped_bin, bin, 'strip $SOURCE -o $TARGET')
307        bin = stripped_bin
308    targets = newEnv.Concat(exe, [bin, 'python/m5py.zip'])
309    newEnv.M5Binary = targets[0]
310    envList.append(newEnv)
311
312# Debug binary
313# Solaris seems to have some issue with DWARF2 debugging information, it's ok
314# with stabs though
315if sys.platform == 'sunos5':
316   debug_flag = '-gstabs+'
317else:
318   debug_flag = '-ggdb3'
319
320makeEnv('debug', '.do',
321        CCFLAGS = Split('%s -O0' % debug_flag),
322        CPPDEFINES = ['DEBUG', 'TRACING_ON=1'])
323
324# Optimized binary
325makeEnv('opt', '.o',
326        CCFLAGS = Split('-g -O3'),
327        CPPDEFINES = ['TRACING_ON=1'])
328
329# "Fast" binary
330makeEnv('fast', '.fo', strip = True,
331        CCFLAGS = Split('-O3'),
332        CPPDEFINES = ['NDEBUG', 'TRACING_ON=0'])
333
334# Profiled binary
335makeEnv('prof', '.po',
336        CCFLAGS = Split('-O3 -g -pg'),
337        CPPDEFINES = ['NDEBUG', 'TRACING_ON=0'],
338        LINKFLAGS = '-pg')
339
340Return('envList')
341