SConscript revision 2568 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29import os
30import sys
31from os.path import isdir
32
33# This file defines how to build a particular configuration of M5
34# based on variable settings in the 'env' build environment.
35
36# Import build environment variable from SConstruct.
37Import('env')
38
39###################################################
40#
41# Define needed sources.
42#
43###################################################
44
45# Base sources used by all configurations.
46
47base_sources = Split('''
48	base/circlebuf.cc
49	base/copyright.cc
50	base/cprintf.cc
51        base/embedfile.cc
52	base/fast_alloc.cc
53	base/fifo_buffer.cc
54	base/hostinfo.cc
55	base/hybrid_pred.cc
56	base/inifile.cc
57	base/intmath.cc
58	base/match.cc
59	base/misc.cc
60	base/output.cc
61	base/pollevent.cc
62	base/range.cc
63	base/random.cc
64	base/sat_counter.cc
65	base/socket.cc
66	base/statistics.cc
67	base/str.cc
68	base/time.cc
69	base/trace.cc
70	base/traceflags.cc
71	base/userinfo.cc
72	base/compression/lzss_compression.cc
73	base/loader/aout_object.cc
74	base/loader/ecoff_object.cc
75	base/loader/elf_object.cc
76	base/loader/object_file.cc
77	base/loader/symtab.cc
78	base/stats/events.cc
79	base/stats/statdb.cc
80	base/stats/visit.cc
81	base/stats/text.cc
82
83	cpu/base.cc
84	cpu/cpu_exec_context.cc
85	cpu/exetrace.cc
86        cpu/op_class.cc
87	cpu/pc_event.cc
88	cpu/static_inst.cc
89        cpu/sampler/sampler.cc
90    
91        mem/bridge.cc
92        mem/bus.cc
93        mem/connector.cc
94        mem/mem_object.cc
95        mem/packet.cc
96        mem/physical.cc
97        mem/port.cc
98        mem/request.cc
99
100        python/pyconfig.cc
101        python/embedded_py.cc
102
103	sim/builder.cc
104	sim/configfile.cc
105	sim/debug.cc
106	sim/eventq.cc
107	sim/faults.cc
108	sim/main.cc
109	sim/param.cc
110	sim/profile.cc
111	sim/root.cc
112	sim/serialize.cc
113	sim/sim_events.cc
114	sim/sim_exit.cc
115	sim/sim_object.cc
116	sim/startup.cc
117	sim/stat_context.cc
118	sim/stat_control.cc
119	sim/system.cc
120	sim/trace_context.cc
121        ''')
122
123# Old FullCPU sources
124full_cpu_sources = Split('''
125	encumbered/cpu/full/bpred.cc
126	encumbered/cpu/full/commit.cc
127	encumbered/cpu/full/cpu.cc
128	encumbered/cpu/full/create_vector.cc
129	encumbered/cpu/full/cv_spec_state.cc
130	encumbered/cpu/full/dd_queue.cc
131	encumbered/cpu/full/dep_link.cc
132	encumbered/cpu/full/dispatch.cc
133	encumbered/cpu/full/dyn_inst.cc
134	encumbered/cpu/full/execute.cc
135	encumbered/cpu/full/fetch.cc
136	encumbered/cpu/full/floss_reasons.cc
137	encumbered/cpu/full/fu_pool.cc
138	encumbered/cpu/full/inst_fifo.cc
139	encumbered/cpu/full/instpipe.cc
140	encumbered/cpu/full/issue.cc
141	encumbered/cpu/full/ls_queue.cc
142	encumbered/cpu/full/machine_queue.cc
143        encumbered/cpu/full/pipetrace.cc
144        encumbered/cpu/full/readyq.cc
145        encumbered/cpu/full/reg_info.cc
146        encumbered/cpu/full/rob_station.cc
147        encumbered/cpu/full/spec_memory.cc
148        encumbered/cpu/full/spec_state.cc
149        encumbered/cpu/full/storebuffer.cc
150        encumbered/cpu/full/writeback.cc
151        encumbered/cpu/full/iq/iq_station.cc
152        encumbered/cpu/full/iq/iqueue.cc
153        encumbered/cpu/full/iq/segmented/chain_info.cc
154        encumbered/cpu/full/iq/segmented/chain_wire.cc
155        encumbered/cpu/full/iq/segmented/iq_seg.cc
156        encumbered/cpu/full/iq/segmented/iq_segmented.cc
157        encumbered/cpu/full/iq/segmented/seg_chain.cc
158        encumbered/cpu/full/iq/seznec/iq_seznec.cc
159        encumbered/cpu/full/iq/standard/iq_standard.cc
160        ''')
161
162trace_reader_sources = Split('''
163        cpu/trace/reader/mem_trace_reader.cc
164        cpu/trace/reader/ibm_reader.cc
165        cpu/trace/reader/itx_reader.cc
166        cpu/trace/reader/m5_reader.cc
167        cpu/trace/opt_cpu.cc
168        cpu/trace/trace_cpu.cc
169        ''')
170
171
172
173# MySql sources
174mysql_sources = Split('''
175	base/mysql.cc
176	base/stats/mysql.cc
177        ''')
178
179# Full-system sources
180full_system_sources = Split('''
181	base/crc.cc
182	base/inet.cc
183	base/remote_gdb.cc
184
185	cpu/intr_control.cc
186        cpu/profile.cc
187
188	dev/alpha_console.cc
189	dev/baddev.cc
190	dev/disk_image.cc
191	dev/etherbus.cc
192	dev/etherdump.cc
193	dev/etherint.cc
194	dev/etherlink.cc
195	dev/etherpkt.cc
196	dev/ethertap.cc	
197        dev/ide_ctrl.cc
198	dev/ide_disk.cc
199	dev/io_device.cc
200	dev/isa_fake.cc
201	dev/ns_gige.cc
202	dev/pciconfigall.cc
203	dev/pcidev.cc
204	dev/pcifake.cc
205	dev/pktfifo.cc
206	dev/platform.cc
207        dev/simconsole.cc
208	dev/simple_disk.cc
209	dev/sinic.cc
210	dev/tsunami.cc
211	dev/tsunami_cchip.cc
212	dev/tsunami_io.cc
213	dev/tsunami_fake.cc
214	dev/tsunami_pchip.cc
215
216	dev/uart.cc
217	dev/uart8250.cc
218
219	kern/kernel_binning.cc
220	kern/kernel_stats.cc
221	kern/system_events.cc
222	kern/linux/events.cc
223	kern/linux/linux_syscalls.cc
224	kern/linux/printk.cc
225
226        mem/vport.cc
227
228	sim/pseudo_inst.cc
229        ''')
230
231
232if env['TARGET_ISA'] == 'alpha':
233    full_system_sources += Split('''
234	kern/tru64/dump_mbuf.cc
235	kern/tru64/printf.cc
236	kern/tru64/tru64_events.cc
237	kern/tru64/tru64_syscalls.cc
238        ''')
239
240# turbolaser encumbered sources
241turbolaser_sources = Split('''
242	encumbered/dev/dma.cc
243	encumbered/dev/etherdev.cc
244	encumbered/dev/scsi.cc
245	encumbered/dev/scsi_ctrl.cc
246	encumbered/dev/scsi_disk.cc
247	encumbered/dev/scsi_none.cc
248	encumbered/dev/tlaser_clock.cc
249	encumbered/dev/tlaser_ipi.cc
250	encumbered/dev/tlaser_mbox.cc
251	encumbered/dev/tlaser_mc146818.cc
252	encumbered/dev/tlaser_node.cc
253	encumbered/dev/tlaser_pcia.cc
254	encumbered/dev/tlaser_pcidev.cc
255	encumbered/dev/tlaser_serial.cc
256	encumbered/dev/turbolaser.cc
257	encumbered/dev/uart8530.cc
258        ''')
259
260# Syscall emulation (non-full-system) sources
261syscall_emulation_sources = Split('''
262        mem/translating_port.cc
263        mem/page_table.cc
264	sim/process.cc
265	sim/syscall_emul.cc
266        ''')
267
268#if env['TARGET_ISA'] == 'alpha':
269#    syscall_emulation_sources += Split('''
270#        kern/tru64/tru64.cc
271#        ''')
272
273alpha_eio_sources = Split('''
274	encumbered/eio/exolex.cc
275	encumbered/eio/libexo.cc
276	encumbered/eio/eio.cc
277        ''')
278
279if env['TARGET_ISA'] == 'ALPHA_ISA':
280    syscall_emulation_sources += alpha_eio_sources
281    
282memtest_sources = Split('''
283	cpu/memtest/memtest.cc
284        ''')
285
286# Add a flag defining what THE_ISA should be for all compilation
287env.Append(CPPDEFINES=[('THE_ISA','%s_ISA' % env['TARGET_ISA'].upper())])
288
289arch_sources = SConscript('arch/SConscript',
290                          exports = 'env', duplicate = False)
291
292cpu_sources = SConscript('cpu/SConscript',
293                         exports = 'env', duplicate = False)
294
295# This is outside of cpu/SConscript since the source directory isn't
296# underneath 'cpu'.
297if 'FullCPU' in env['CPU_MODELS']:
298    cpu_sources += full_cpu_sources
299
300# Set up complete list of sources based on configuration.
301sources = base_sources + arch_sources + cpu_sources
302
303if env['FULL_SYSTEM']:
304    sources += full_system_sources
305    if env['ALPHA_TLASER']:
306        sources += turbolaser_sources
307else:
308    sources += syscall_emulation_sources
309
310if env['USE_MYSQL']:
311    sources += mysql_sources
312
313for opt in env.ExportOptions:
314    env.ConfigFile(opt)
315
316###################################################
317#
318# Special build rules.
319#
320###################################################
321
322# base/traceflags.{cc,hh} are generated from base/traceflags.py.
323# $TARGET.base will expand to "<build-dir>/base/traceflags".
324env.Command(Split('base/traceflags.hh base/traceflags.cc'),
325            'base/traceflags.py',
326            'python $SOURCE $TARGET.base')
327
328# libelf build is described in its own SConscript file.
329# SConscript-local is the per-config build, which just copies some
330# header files into a place where they can be found.
331SConscript('libelf/SConscript-local', exports = 'env', duplicate=0)
332SConscript('python/SConscript', exports = ['env'], duplicate=0)
333
334# This function adds the specified sources to the given build
335# environment, and returns a list of all the corresponding SCons
336# Object nodes (including an extra one for date.cc).  We explicitly
337# add the Object nodes so we can set up special dependencies for
338# date.cc.
339def make_objs(sources, env):
340    objs = [env.Object(s) for s in sources]
341    # make date.cc depend on all other objects so it always gets
342    # recompiled whenever anything else does
343    date_obj = env.Object('base/date.cc')
344    env.Depends(date_obj, objs)
345    objs.append(date_obj)
346    return objs
347
348###################################################
349#
350# Define binaries.  Each different build type (debug, opt, etc.) gets
351# a slightly different build environment.
352#
353###################################################
354
355# Include file paths are rooted in this directory.  SCons will
356# automatically expand '.' to refer to both the source directory and
357# the corresponding build directory to pick up generated include
358# files.
359env.Append(CPPPATH='.')
360env.Append(CPPPATH='./libelf')
361
362# Debug binary
363debugEnv = env.Copy(OBJSUFFIX='.do')
364debugEnv.Label = 'debug'
365debugEnv.Append(CCFLAGS=Split('-g3 -gdwarf-2 -O0'))
366debugEnv.Append(CPPDEFINES='DEBUG')
367tlist = debugEnv.Program(target = 'm5.debug',
368                         source = make_objs(sources, debugEnv))
369debugEnv.M5Binary = tlist[0]
370
371# Optimized binary
372optEnv = env.Copy()
373optEnv.Label = 'opt'
374optEnv.Append(CCFLAGS=Split('-g -O3'))
375tlist = optEnv.Program(target = 'm5.opt',
376                       source = make_objs(sources, optEnv))
377optEnv.M5Binary = tlist[0]
378
379# "Fast" binary
380fastEnv = env.Copy(OBJSUFFIX='.fo')
381fastEnv.Label = 'fast'
382fastEnv.Append(CCFLAGS=Split('-O3'))
383fastEnv.Append(CPPDEFINES='NDEBUG')
384fastEnv.Program(target = 'm5.fast.unstripped',
385                source = make_objs(sources, fastEnv))
386tlist = fastEnv.Command(target = 'm5.fast',
387                        source = 'm5.fast.unstripped',
388                        action = 'strip $SOURCE -o $TARGET')
389fastEnv.M5Binary = tlist[0]
390
391# Profiled binary
392profEnv = env.Copy(OBJSUFFIX='.po')
393profEnv.Label = 'prof'
394profEnv.Append(CCFLAGS=Split('-O3 -g -pg'), LINKFLAGS='-pg')
395tlist = profEnv.Program(target = 'm5.prof',
396                        source = make_objs(sources, profEnv))
397profEnv.M5Binary = tlist[0]
398
399envList = [debugEnv, optEnv, fastEnv, profEnv]
400
401Return('envList')
402