SConscript revision 2560 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29import os
30import sys
31from os.path import isdir
32
33# This file defines how to build a particular configuration of M5
34# based on variable settings in the 'env' build environment.
35
36# Import build environment variable from SConstruct.
37Import('env')
38
39###################################################
40#
41# Define needed sources.
42#
43###################################################
44
45# Base sources used by all configurations.
46
47base_sources = Split('''
48	base/circlebuf.cc
49	base/copyright.cc
50	base/cprintf.cc
51        base/embedfile.cc
52	base/fast_alloc.cc
53	base/fifo_buffer.cc
54	base/hostinfo.cc
55	base/hybrid_pred.cc
56	base/inifile.cc
57	base/intmath.cc
58	base/match.cc
59	base/misc.cc
60	base/output.cc
61	base/pollevent.cc
62	base/range.cc
63	base/random.cc
64	base/sat_counter.cc
65	base/socket.cc
66	base/statistics.cc
67	base/str.cc
68	base/time.cc
69	base/trace.cc
70	base/traceflags.cc
71	base/userinfo.cc
72	base/compression/lzss_compression.cc
73	base/loader/aout_object.cc
74	base/loader/ecoff_object.cc
75	base/loader/elf_object.cc
76	base/loader/object_file.cc
77	base/loader/symtab.cc
78	base/stats/events.cc
79	base/stats/statdb.cc
80	base/stats/visit.cc
81	base/stats/text.cc
82
83	cpu/base.cc
84	cpu/cpu_exec_context.cc
85	cpu/exetrace.cc
86        cpu/op_class.cc
87	cpu/pc_event.cc
88	cpu/static_inst.cc
89        cpu/sampler/sampler.cc
90
91        mem/request.cc
92        mem/connector.cc
93        mem/mem_object.cc
94        mem/physical.cc
95        mem/port.cc
96        mem/bus.cc
97
98        python/pyconfig.cc
99        python/embedded_py.cc
100
101	sim/builder.cc
102	sim/configfile.cc
103	sim/debug.cc
104	sim/eventq.cc
105	sim/faults.cc
106	sim/main.cc
107	sim/param.cc
108	sim/profile.cc
109	sim/root.cc
110	sim/serialize.cc
111	sim/sim_events.cc
112	sim/sim_exit.cc
113	sim/sim_object.cc
114	sim/startup.cc
115	sim/stat_context.cc
116	sim/stat_control.cc
117	sim/system.cc
118	sim/trace_context.cc
119        ''')
120
121# Old FullCPU sources
122full_cpu_sources = Split('''
123	encumbered/cpu/full/bpred.cc
124	encumbered/cpu/full/commit.cc
125	encumbered/cpu/full/cpu.cc
126	encumbered/cpu/full/create_vector.cc
127	encumbered/cpu/full/cv_spec_state.cc
128	encumbered/cpu/full/dd_queue.cc
129	encumbered/cpu/full/dep_link.cc
130	encumbered/cpu/full/dispatch.cc
131	encumbered/cpu/full/dyn_inst.cc
132	encumbered/cpu/full/execute.cc
133	encumbered/cpu/full/fetch.cc
134	encumbered/cpu/full/floss_reasons.cc
135	encumbered/cpu/full/fu_pool.cc
136	encumbered/cpu/full/inst_fifo.cc
137	encumbered/cpu/full/instpipe.cc
138	encumbered/cpu/full/issue.cc
139	encumbered/cpu/full/ls_queue.cc
140	encumbered/cpu/full/machine_queue.cc
141        encumbered/cpu/full/pipetrace.cc
142        encumbered/cpu/full/readyq.cc
143        encumbered/cpu/full/reg_info.cc
144        encumbered/cpu/full/rob_station.cc
145        encumbered/cpu/full/spec_memory.cc
146        encumbered/cpu/full/spec_state.cc
147        encumbered/cpu/full/storebuffer.cc
148        encumbered/cpu/full/writeback.cc
149        encumbered/cpu/full/iq/iq_station.cc
150        encumbered/cpu/full/iq/iqueue.cc
151        encumbered/cpu/full/iq/segmented/chain_info.cc
152        encumbered/cpu/full/iq/segmented/chain_wire.cc
153        encumbered/cpu/full/iq/segmented/iq_seg.cc
154        encumbered/cpu/full/iq/segmented/iq_segmented.cc
155        encumbered/cpu/full/iq/segmented/seg_chain.cc
156        encumbered/cpu/full/iq/seznec/iq_seznec.cc
157        encumbered/cpu/full/iq/standard/iq_standard.cc
158        ''')
159
160trace_reader_sources = Split('''
161        cpu/trace/reader/mem_trace_reader.cc
162        cpu/trace/reader/ibm_reader.cc
163        cpu/trace/reader/itx_reader.cc
164        cpu/trace/reader/m5_reader.cc
165        cpu/trace/opt_cpu.cc
166        cpu/trace/trace_cpu.cc
167        ''')
168
169
170
171# MySql sources
172mysql_sources = Split('''
173	base/mysql.cc
174	base/stats/mysql.cc
175        ''')
176
177# Full-system sources
178full_system_sources = Split('''
179	base/crc.cc
180	base/inet.cc
181	base/remote_gdb.cc
182
183	cpu/intr_control.cc
184        cpu/profile.cc
185
186	dev/alpha_console.cc
187	dev/baddev.cc
188	dev/disk_image.cc
189	dev/io_device.cc
190	dev/isa_fake.cc
191	dev/pciconfigall.cc
192	dev/platform.cc
193        dev/simconsole.cc
194	dev/simple_disk.cc
195	dev/tsunami.cc
196	dev/tsunami_cchip.cc
197	dev/tsunami_io.cc
198	dev/tsunami_fake.cc
199	dev/tsunami_pchip.cc
200
201	dev/uart.cc
202	dev/uart8250.cc
203
204	kern/kernel_binning.cc
205	kern/kernel_stats.cc
206	kern/system_events.cc
207	kern/linux/events.cc
208	kern/linux/linux_syscalls.cc
209	kern/linux/printk.cc
210
211        mem/vport.cc
212
213	sim/pseudo_inst.cc
214        ''')
215
216#	dev/etherbus.cc
217#	dev/etherdump.cc
218#	dev/etherint.cc
219#	dev/etherlink.cc
220#	dev/etherpkt.cc
221#	dev/ethertap.cc
222#	dev/ide_ctrl.cc
223#	dev/ide_disk.cc
224#	dev/ns_gige.cc
225#	dev/pcidev.cc
226#	dev/pcifake.cc
227#	dev/pktfifo.cc
228#	dev/sinic.cc
229
230if env['TARGET_ISA'] == 'alpha':
231    full_system_sources += Split('''
232	kern/tru64/dump_mbuf.cc
233	kern/tru64/printf.cc
234	kern/tru64/tru64_events.cc
235	kern/tru64/tru64_syscalls.cc
236        ''')
237
238# turbolaser encumbered sources
239turbolaser_sources = Split('''
240	encumbered/dev/dma.cc
241	encumbered/dev/etherdev.cc
242	encumbered/dev/scsi.cc
243	encumbered/dev/scsi_ctrl.cc
244	encumbered/dev/scsi_disk.cc
245	encumbered/dev/scsi_none.cc
246	encumbered/dev/tlaser_clock.cc
247	encumbered/dev/tlaser_ipi.cc
248	encumbered/dev/tlaser_mbox.cc
249	encumbered/dev/tlaser_mc146818.cc
250	encumbered/dev/tlaser_node.cc
251	encumbered/dev/tlaser_pcia.cc
252	encumbered/dev/tlaser_pcidev.cc
253	encumbered/dev/tlaser_serial.cc
254	encumbered/dev/turbolaser.cc
255	encumbered/dev/uart8530.cc
256        ''')
257
258# Syscall emulation (non-full-system) sources
259syscall_emulation_sources = Split('''
260        mem/translating_port.cc
261        mem/page_table.cc
262	sim/process.cc
263	sim/syscall_emul.cc
264        ''')
265
266#if env['TARGET_ISA'] == 'alpha':
267#    syscall_emulation_sources += Split('''
268#        kern/tru64/tru64.cc
269#        ''')
270
271alpha_eio_sources = Split('''
272	encumbered/eio/exolex.cc
273	encumbered/eio/libexo.cc
274	encumbered/eio/eio.cc
275        ''')
276
277if env['TARGET_ISA'] == 'ALPHA_ISA':
278    syscall_emulation_sources += alpha_eio_sources
279    
280memtest_sources = Split('''
281	cpu/memtest/memtest.cc
282        ''')
283
284# Add a flag defining what THE_ISA should be for all compilation
285env.Append(CPPDEFINES=[('THE_ISA','%s_ISA' % env['TARGET_ISA'].upper())])
286
287arch_sources = SConscript('arch/SConscript',
288                          exports = 'env', duplicate = False)
289
290cpu_sources = SConscript('cpu/SConscript',
291                         exports = 'env', duplicate = False)
292
293# This is outside of cpu/SConscript since the source directory isn't
294# underneath 'cpu'.
295if 'FullCPU' in env['CPU_MODELS']:
296    cpu_sources += full_cpu_sources
297
298# Set up complete list of sources based on configuration.
299sources = base_sources + arch_sources + cpu_sources
300
301if env['FULL_SYSTEM']:
302    sources += full_system_sources
303    if env['ALPHA_TLASER']:
304        sources += turbolaser_sources
305else:
306    sources += syscall_emulation_sources
307
308if env['USE_MYSQL']:
309    sources += mysql_sources
310
311for opt in env.ExportOptions:
312    env.ConfigFile(opt)
313
314###################################################
315#
316# Special build rules.
317#
318###################################################
319
320# base/traceflags.{cc,hh} are generated from base/traceflags.py.
321# $TARGET.base will expand to "<build-dir>/base/traceflags".
322env.Command(Split('base/traceflags.hh base/traceflags.cc'),
323            'base/traceflags.py',
324            'python $SOURCE $TARGET.base')
325
326# libelf build is described in its own SConscript file.
327# SConscript-local is the per-config build, which just copies some
328# header files into a place where they can be found.
329SConscript('libelf/SConscript-local', exports = 'env', duplicate=0)
330SConscript('python/SConscript', exports = ['env'], duplicate=0)
331
332# This function adds the specified sources to the given build
333# environment, and returns a list of all the corresponding SCons
334# Object nodes (including an extra one for date.cc).  We explicitly
335# add the Object nodes so we can set up special dependencies for
336# date.cc.
337def make_objs(sources, env):
338    objs = [env.Object(s) for s in sources]
339    # make date.cc depend on all other objects so it always gets
340    # recompiled whenever anything else does
341    date_obj = env.Object('base/date.cc')
342    env.Depends(date_obj, objs)
343    objs.append(date_obj)
344    return objs
345
346###################################################
347#
348# Define binaries.  Each different build type (debug, opt, etc.) gets
349# a slightly different build environment.
350#
351###################################################
352
353# Include file paths are rooted in this directory.  SCons will
354# automatically expand '.' to refer to both the source directory and
355# the corresponding build directory to pick up generated include
356# files.
357env.Append(CPPPATH='.')
358env.Append(CPPPATH='./libelf')
359
360# Debug binary
361debugEnv = env.Copy(OBJSUFFIX='.do')
362debugEnv.Label = 'debug'
363debugEnv.Append(CCFLAGS=Split('-g3 -gdwarf-2 -O0'))
364debugEnv.Append(CPPDEFINES='DEBUG')
365tlist = debugEnv.Program(target = 'm5.debug',
366                         source = make_objs(sources, debugEnv))
367debugEnv.M5Binary = tlist[0]
368
369# Optimized binary
370optEnv = env.Copy()
371optEnv.Label = 'opt'
372optEnv.Append(CCFLAGS=Split('-g -O3'))
373tlist = optEnv.Program(target = 'm5.opt',
374                       source = make_objs(sources, optEnv))
375optEnv.M5Binary = tlist[0]
376
377# "Fast" binary
378fastEnv = env.Copy(OBJSUFFIX='.fo')
379fastEnv.Label = 'fast'
380fastEnv.Append(CCFLAGS=Split('-O3'))
381fastEnv.Append(CPPDEFINES='NDEBUG')
382fastEnv.Program(target = 'm5.fast.unstripped',
383                source = make_objs(sources, fastEnv))
384tlist = fastEnv.Command(target = 'm5.fast',
385                        source = 'm5.fast.unstripped',
386                        action = 'strip $SOURCE -o $TARGET')
387fastEnv.M5Binary = tlist[0]
388
389# Profiled binary
390profEnv = env.Copy(OBJSUFFIX='.po')
391profEnv.Label = 'prof'
392profEnv.Append(CCFLAGS=Split('-O3 -g -pg'), LINKFLAGS='-pg')
393tlist = profEnv.Program(target = 'm5.prof',
394                        source = make_objs(sources, profEnv))
395profEnv.M5Binary = tlist[0]
396
397envList = [debugEnv, optEnv, fastEnv, profEnv]
398
399Return('envList')
400