pybind11Tools.cmake revision 12037:d28054ac6ec9 
1# tools/pybind11Tools.cmake -- Build system for the pybind11 modules
2#
3# Copyright (c) 2015 Wenzel Jakob <wenzel@inf.ethz.ch>
4#
5# All rights reserved. Use of this source code is governed by a
6# BSD-style license that can be found in the LICENSE file.
7
8cmake_minimum_required(VERSION 2.8.12)
9
10# Add a CMake parameter for choosing a desired Python version
11if(NOT PYBIND11_PYTHON_VERSION)
12  set(PYBIND11_PYTHON_VERSION "" CACHE STRING "Python version to use for compiling modules")
13endif()
14
15set(Python_ADDITIONAL_VERSIONS 3.7 3.6 3.5 3.4)
16find_package(PythonLibsNew ${PYBIND11_PYTHON_VERSION} REQUIRED)
17
18include(CheckCXXCompilerFlag)
19include(CMakeParseArguments)
20
21function(select_cxx_standard)
22  if(NOT MSVC AND NOT PYBIND11_CPP_STANDARD)
23    check_cxx_compiler_flag("-std=c++14" HAS_CPP14_FLAG)
24    check_cxx_compiler_flag("-std=c++11" HAS_CPP11_FLAG)
25
26    if (HAS_CPP14_FLAG)
27      set(PYBIND11_CPP_STANDARD -std=c++14)
28    elseif (HAS_CPP11_FLAG)
29      set(PYBIND11_CPP_STANDARD -std=c++11)
30    else()
31      message(FATAL_ERROR "Unsupported compiler -- pybind11 requires C++11 support!")
32    endif()
33
34    set(PYBIND11_CPP_STANDARD ${PYBIND11_CPP_STANDARD} CACHE STRING
35        "C++ standard flag, e.g. -std=c++11 or -std=c++14. Defaults to latest available." FORCE)
36  endif()
37endfunction()
38
39# Checks whether the given CXX/linker flags can compile and link a cxx file.  cxxflags and
40# linkerflags are lists of flags to use.  The result variable is a unique variable name for each set
41# of flags: the compilation result will be cached base on the result variable.  If the flags work,
42# sets them in cxxflags_out/linkerflags_out internal cache variables (in addition to ${result}).
43function(_pybind11_return_if_cxx_and_linker_flags_work result cxxflags linkerflags cxxflags_out linkerflags_out)
44  set(CMAKE_REQUIRED_LIBRARIES ${linkerflags})
45  check_cxx_compiler_flag("${cxxflags}" ${result})
46  if (${result})
47    set(${cxxflags_out} "${cxxflags}" CACHE INTERNAL "" FORCE)
48    set(${linkerflags_out} "${linkerflags}" CACHE INTERNAL "" FORCE)
49  endif()
50endfunction()
51
52# Internal: find the appropriate link time optimization flags for this compiler
53function(_pybind11_add_lto_flags target_name prefer_thin_lto)
54  if (NOT DEFINED PYBIND11_LTO_CXX_FLAGS)
55    set(PYBIND11_LTO_CXX_FLAGS "" CACHE INTERNAL "")
56    set(PYBIND11_LTO_LINKER_FLAGS "" CACHE INTERNAL "")
57
58    if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
59      set(cxx_append "")
60      set(linker_append "")
61      if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND NOT APPLE)
62        # Clang Gold plugin does not support -Os; append -O3 to MinSizeRel builds to override it
63        set(linker_append ";$<$<CONFIG:MinSizeRel>:-O3>")
64      elseif(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
65        set(cxx_append ";-fno-fat-lto-objects")
66      endif()
67
68      if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND prefer_thin_lto)
69        _pybind11_return_if_cxx_and_linker_flags_work(HAS_FLTO_THIN
70          "-flto=thin${cxx_append}" "-flto=thin${linker_append}"
71          PYBIND11_LTO_CXX_FLAGS PYBIND11_LTO_LINKER_FLAGS)
72      endif()
73
74      if (NOT HAS_FLTO_THIN)
75        _pybind11_return_if_cxx_and_linker_flags_work(HAS_FLTO
76          "-flto${cxx_append}" "-flto${linker_append}"
77          PYBIND11_LTO_CXX_FLAGS PYBIND11_LTO_LINKER_FLAGS)
78      endif()
79    elseif (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
80      # Intel equivalent to LTO is called IPO
81      _pybind11_return_if_cxx_and_linker_flags_work(HAS_INTEL_IPO
82      "-ipo" "-ipo" PYBIND11_LTO_CXX_FLAGS PYBIND11_LTO_LINKER_FLAGS)
83    elseif(MSVC)
84      # cmake only interprets libraries as linker flags when they start with a - (otherwise it
85      # converts /LTCG to \LTCG as if it was a Windows path).  Luckily MSVC supports passing flags
86      # with - instead of /, even if it is a bit non-standard:
87      _pybind11_return_if_cxx_and_linker_flags_work(HAS_MSVC_GL_LTCG
88        "/GL" "-LTCG" PYBIND11_LTO_CXX_FLAGS PYBIND11_LTO_LINKER_FLAGS)
89    endif()
90
91    if (PYBIND11_LTO_CXX_FLAGS)
92      message(STATUS "LTO enabled")
93    else()
94      message(STATUS "LTO disabled (not supported by the compiler and/or linker)")
95    endif()
96  endif()
97
98  # Enable LTO flags if found, except for Debug builds
99  if (PYBIND11_LTO_CXX_FLAGS)
100    target_compile_options(${target_name} PRIVATE "$<$<NOT:$<CONFIG:Debug>>:${PYBIND11_LTO_CXX_FLAGS}>")
101  endif()
102  if (PYBIND11_LTO_LINKER_FLAGS)
103    target_link_libraries(${target_name} PRIVATE "$<$<NOT:$<CONFIG:Debug>>:${PYBIND11_LTO_LINKER_FLAGS}>")
104  endif()
105endfunction()
106
107# Build a Python extension module:
108# pybind11_add_module(<name> [MODULE | SHARED] [EXCLUDE_FROM_ALL]
109#                     [NO_EXTRAS] [THIN_LTO] source1 [source2 ...])
110#
111function(pybind11_add_module target_name)
112  set(options MODULE SHARED EXCLUDE_FROM_ALL NO_EXTRAS THIN_LTO)
113  cmake_parse_arguments(ARG "${options}" "" "" ${ARGN})
114
115  if(ARG_MODULE AND ARG_SHARED)
116    message(FATAL_ERROR "Can't be both MODULE and SHARED")
117  elseif(ARG_SHARED)
118    set(lib_type SHARED)
119  else()
120    set(lib_type MODULE)
121  endif()
122
123  if(ARG_EXCLUDE_FROM_ALL)
124    set(exclude_from_all EXCLUDE_FROM_ALL)
125  endif()
126
127  add_library(${target_name} ${lib_type} ${exclude_from_all} ${ARG_UNPARSED_ARGUMENTS})
128
129  target_include_directories(${target_name}
130    PRIVATE ${PYBIND11_INCLUDE_DIR}  # from project CMakeLists.txt
131    PRIVATE ${pybind11_INCLUDE_DIR}  # from pybind11Config
132    PRIVATE ${PYTHON_INCLUDE_DIRS})
133
134  # The prefix and extension are provided by FindPythonLibsNew.cmake
135  set_target_properties(${target_name} PROPERTIES PREFIX "${PYTHON_MODULE_PREFIX}")
136  set_target_properties(${target_name} PROPERTIES SUFFIX "${PYTHON_MODULE_EXTENSION}")
137
138  if(WIN32 OR CYGWIN)
139    # Link against the Python shared library on Windows
140    target_link_libraries(${target_name} PRIVATE ${PYTHON_LIBRARIES})
141  elseif(APPLE)
142    # It's quite common to have multiple copies of the same Python version
143    # installed on one's system. E.g.: one copy from the OS and another copy
144    # that's statically linked into an application like Blender or Maya.
145    # If we link our plugin library against the OS Python here and import it
146    # into Blender or Maya later on, this will cause segfaults when multiple
147    # conflicting Python instances are active at the same time (even when they
148    # are of the same version).
149
150    # Windows is not affected by this issue since it handles DLL imports
151    # differently. The solution for Linux and Mac OS is simple: we just don't
152    # link against the Python library. The resulting shared library will have
153    # missing symbols, but that's perfectly fine -- they will be resolved at
154    # import time.
155
156    target_link_libraries(${target_name} PRIVATE "-undefined dynamic_lookup")
157
158    if(ARG_SHARED)
159      # Suppress CMake >= 3.0 warning for shared libraries
160      set_target_properties(${target_name} PROPERTIES MACOSX_RPATH ON)
161    endif()
162  endif()
163
164  select_cxx_standard()
165  if(NOT MSVC)
166    # Make sure C++11/14 are enabled
167    target_compile_options(${target_name} PUBLIC ${PYBIND11_CPP_STANDARD})
168  endif()
169
170  if(ARG_NO_EXTRAS)
171    return()
172  endif()
173
174  _pybind11_add_lto_flags(${target_name} ${ARG_THIN_LTO})
175
176  if (NOT MSVC AND NOT ${CMAKE_BUILD_TYPE} MATCHES Debug)
177    # Set the default symbol visibility to hidden (very important to obtain small binaries)
178    target_compile_options(${target_name} PRIVATE "-fvisibility=hidden")
179
180    # Strip unnecessary sections of the binary on Linux/Mac OS
181    if(CMAKE_STRIP)
182      if(APPLE)
183        add_custom_command(TARGET ${target_name} POST_BUILD
184                           COMMAND ${CMAKE_STRIP} -x $<TARGET_FILE:${target_name}>)
185      else()
186        add_custom_command(TARGET ${target_name} POST_BUILD
187                           COMMAND ${CMAKE_STRIP} $<TARGET_FILE:${target_name}>)
188      endif()
189    endif()
190  endif()
191
192  if(MSVC)
193    # /MP enables multithreaded builds (relevant when there are many files), /bigobj is
194    # needed for bigger binding projects due to the limit to 64k addressable sections
195    target_compile_options(${target_name} PRIVATE /MP /bigobj)
196  endif()
197endfunction()
198