pybind11Config.cmake.in revision 12037:d28054ac6ec9 
1# pybind11Config.cmake
2# --------------------
3#
4# PYBIND11 cmake module.
5# This module sets the following variables in your project::
6#
7#   pybind11_FOUND - true if pybind11 and all required components found on the system
8#   pybind11_VERSION - pybind11 version in format Major.Minor.Release
9#   pybind11_INCLUDE_DIRS - Directories where pybind11 and python headers are located.
10#   pybind11_INCLUDE_DIR - Directory where pybind11 headers are located.
11#   pybind11_DEFINITIONS - Definitions necessary to use pybind11, namely USING_pybind11.
12#   pybind11_LIBRARIES - compile flags and python libraries (as needed) to link against.
13#   pybind11_LIBRARY - empty.
14#   CMAKE_MODULE_PATH - appends location of accompanying FindPythonLibsNew.cmake and
15#                       pybind11Tools.cmake modules.
16#
17#
18# Available components: None
19#
20#
21# Exported targets::
22#
23# If pybind11 is found, this module defines the following :prop_tgt:`IMPORTED`
24# target. Python headers, libraries (as needed by platform), and C++ standard
25# are attached to the target. Set PythonLibsNew variables to influence
26# python detection and PYBIND11_CPP_STANDARD (-std=c++11 or -std=c++14) to
27# influence standard setting. ::
28#
29#   pybind11::module - the main pybind11 interface library for extension modules (i.e., headers)
30#
31#   find_package(pybind11 CONFIG REQUIRED)
32#   message(STATUS "Found pybind11: ${pybind11_INCLUDE_DIR} (found version ${pybind11_VERSION} & Py${PYTHON_VERSION_STRING})")
33#   add_library(mylib MODULE main.cpp)
34#   target_link_libraries(mylib pybind11::module)
35#
36# Suggested usage::
37#
38# find_package with version info is not recommended except for release versions. ::
39#
40#   find_package(pybind11 CONFIG)
41#   find_package(pybind11 2.0 EXACT CONFIG REQUIRED)
42#
43#
44# The following variables can be set to guide the search for this package::
45#
46#   pybind11_DIR - CMake variable, set to directory containing this Config file
47#   CMAKE_PREFIX_PATH - CMake variable, set to root directory of this package
48#   PATH - environment variable, set to bin directory of this package
49#   CMAKE_DISABLE_FIND_PACKAGE_pybind11 - CMake variable, disables
50#     find_package(pybind11) when not REQUIRED, perhaps to force internal build
51
52@PACKAGE_INIT@
53
54set(PN pybind11)
55
56# location of pybind11/pybind11.h
57set(${PN}_INCLUDE_DIR "${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_INCLUDEDIR@")
58
59set(${PN}_LIBRARY "")
60set(${PN}_DEFINITIONS USING_${PN})
61
62check_required_components(${PN})
63
64# make detectable the FindPythonLibsNew.cmake module
65list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
66
67include(pybind11Tools)
68
69if(NOT (CMAKE_VERSION VERSION_LESS 3.0))
70#-----------------------------------------------------------------------------
71# Don't include targets if this file is being picked up by another
72# project which has already built this as a subproject
73#-----------------------------------------------------------------------------
74if(NOT TARGET ${PN}::module)
75    include("${CMAKE_CURRENT_LIST_DIR}/${PN}Targets.cmake")
76
77    find_package(PythonLibsNew ${PYBIND11_PYTHON_VERSION} MODULE REQUIRED)
78    set_property(TARGET ${PN}::module APPEND PROPERTY INTERFACE_INCLUDE_DIRECTORIES ${PYTHON_INCLUDE_DIRS})
79    if(WIN32 OR CYGWIN)
80      set_property(TARGET ${PN}::module APPEND PROPERTY INTERFACE_LINK_LIBRARIES ${PYTHON_LIBRARIES})
81    endif()
82
83    select_cxx_standard()
84    set_property(TARGET ${PN}::module APPEND PROPERTY INTERFACE_COMPILE_OPTIONS "${PYBIND11_CPP_STANDARD}")
85
86    get_property(_iid TARGET ${PN}::module PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
87    get_property(_ill TARGET ${PN}::module PROPERTY INTERFACE_LINK_LIBRARIES)
88    get_property(_ico TARGET ${PN}::module PROPERTY INTERFACE_COMPILE_OPTIONS)
89    set(${PN}_INCLUDE_DIRS ${_iid})
90    set(${PN}_LIBRARIES ${_ico} ${_ill})
91endif()
92endif()
93