FindPythonLibsNew.cmake revision 11986:c12e4625ab56 
1# - Find python libraries
2# This module finds the libraries corresponding to the Python interpeter
3# FindPythonInterp provides.
4# This code sets the following variables:
5#
6#  PYTHONLIBS_FOUND           - have the Python libs been found
7#  PYTHON_PREFIX              - path to the Python installation
8#  PYTHON_LIBRARIES           - path to the python library
9#  PYTHON_INCLUDE_DIRS        - path to where Python.h is found
10#  PYTHON_MODULE_EXTENSION    - lib extension, e.g. '.so' or '.pyd'
11#  PYTHON_MODULE_PREFIX       - lib name prefix: usually an empty string
12#  PYTHON_SITE_PACKAGES       - path to installation site-packages
13#  PYTHON_IS_DEBUG            - whether the Python interpreter is a debug build
14#
15# Thanks to talljimbo for the patch adding the 'LDVERSION' config
16# variable usage.
17
18#=============================================================================
19# Copyright 2001-2009 Kitware, Inc.
20# Copyright 2012 Continuum Analytics, Inc.
21#
22# All rights reserved.
23#
24# Redistribution and use in source and binary forms, with or without
25# modification, are permitted provided that the following conditions
26# are met:
27#
28# * Redistributions of source code must retain the above copyright
29# notice, this list of conditions and the following disclaimer.
30#
31# * Redistributions in binary form must reproduce the above copyright
32# notice, this list of conditions and the following disclaimer in the
33# documentation and/or other materials provided with the distribution.
34#
35# * Neither the names of Kitware, Inc., the Insight Software Consortium,
36# nor the names of their contributors may be used to endorse or promote
37# products derived from this software without specific prior written
38# permission.
39#
40# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
41# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
42# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
43# # A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
44# HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
45# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
46# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
47# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
48# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
49# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
50# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
51#=============================================================================
52
53if(PYTHONLIBS_FOUND)
54    return()
55endif()
56
57# Use the Python interpreter to find the libs.
58if(PythonLibsNew_FIND_REQUIRED)
59    find_package(PythonInterp ${PythonLibsNew_FIND_VERSION} REQUIRED)
60else()
61    find_package(PythonInterp ${PythonLibsNew_FIND_VERSION})
62endif()
63
64if(NOT PYTHONINTERP_FOUND)
65    set(PYTHONLIBS_FOUND FALSE)
66    return()
67endif()
68
69# According to http://stackoverflow.com/questions/646518/python-how-to-detect-debug-interpreter
70# testing whether sys has the gettotalrefcount function is a reliable, cross-platform
71# way to detect a CPython debug interpreter.
72#
73# The library suffix is from the config var LDVERSION sometimes, otherwise
74# VERSION. VERSION will typically be like "2.7" on unix, and "27" on windows.
75execute_process(COMMAND "${PYTHON_EXECUTABLE}" "-c"
76    "from distutils import sysconfig as s;import sys;import struct;
77print('.'.join(str(v) for v in sys.version_info));
78print(sys.prefix);
79print(s.get_python_inc(plat_specific=True));
80print(s.get_python_lib(plat_specific=True));
81print(s.get_config_var('SO'));
82print(hasattr(sys, 'gettotalrefcount')+0);
83print(struct.calcsize('@P'));
84print(s.get_config_var('LDVERSION') or s.get_config_var('VERSION'));
85print(s.get_config_var('LIBDIR') or '');
86print(s.get_config_var('MULTIARCH') or '');
87"
88    RESULT_VARIABLE _PYTHON_SUCCESS
89    OUTPUT_VARIABLE _PYTHON_VALUES
90    ERROR_VARIABLE _PYTHON_ERROR_VALUE)
91
92if(NOT _PYTHON_SUCCESS MATCHES 0)
93    if(PythonLibsNew_FIND_REQUIRED)
94        message(FATAL_ERROR
95            "Python config failure:\n${_PYTHON_ERROR_VALUE}")
96    endif()
97    set(PYTHONLIBS_FOUND FALSE)
98    return()
99endif()
100
101# Convert the process output into a list
102string(REGEX REPLACE ";" "\\\\;" _PYTHON_VALUES ${_PYTHON_VALUES})
103string(REGEX REPLACE "\n" ";" _PYTHON_VALUES ${_PYTHON_VALUES})
104list(GET _PYTHON_VALUES 0 _PYTHON_VERSION_LIST)
105list(GET _PYTHON_VALUES 1 PYTHON_PREFIX)
106list(GET _PYTHON_VALUES 2 PYTHON_INCLUDE_DIR)
107list(GET _PYTHON_VALUES 3 PYTHON_SITE_PACKAGES)
108list(GET _PYTHON_VALUES 4 PYTHON_MODULE_EXTENSION)
109list(GET _PYTHON_VALUES 5 PYTHON_IS_DEBUG)
110list(GET _PYTHON_VALUES 6 PYTHON_SIZEOF_VOID_P)
111list(GET _PYTHON_VALUES 7 PYTHON_LIBRARY_SUFFIX)
112list(GET _PYTHON_VALUES 8 PYTHON_LIBDIR)
113list(GET _PYTHON_VALUES 9 PYTHON_MULTIARCH)
114
115# Make sure the Python has the same pointer-size as the chosen compiler
116# Skip if CMAKE_SIZEOF_VOID_P is not defined
117if(CMAKE_SIZEOF_VOID_P AND (NOT "${PYTHON_SIZEOF_VOID_P}" STREQUAL "${CMAKE_SIZEOF_VOID_P}"))
118    if(PythonLibsNew_FIND_REQUIRED)
119        math(EXPR _PYTHON_BITS "${PYTHON_SIZEOF_VOID_P} * 8")
120        math(EXPR _CMAKE_BITS "${CMAKE_SIZEOF_VOID_P} * 8")
121        message(FATAL_ERROR
122            "Python config failure: Python is ${_PYTHON_BITS}-bit, "
123            "chosen compiler is  ${_CMAKE_BITS}-bit")
124    endif()
125    set(PYTHONLIBS_FOUND FALSE)
126    return()
127endif()
128
129# The built-in FindPython didn't always give the version numbers
130string(REGEX REPLACE "\\." ";" _PYTHON_VERSION_LIST ${_PYTHON_VERSION_LIST})
131list(GET _PYTHON_VERSION_LIST 0 PYTHON_VERSION_MAJOR)
132list(GET _PYTHON_VERSION_LIST 1 PYTHON_VERSION_MINOR)
133list(GET _PYTHON_VERSION_LIST 2 PYTHON_VERSION_PATCH)
134
135# Make sure all directory separators are '/'
136string(REGEX REPLACE "\\\\" "/" PYTHON_PREFIX ${PYTHON_PREFIX})
137string(REGEX REPLACE "\\\\" "/" PYTHON_INCLUDE_DIR ${PYTHON_INCLUDE_DIR})
138string(REGEX REPLACE "\\\\" "/" PYTHON_SITE_PACKAGES ${PYTHON_SITE_PACKAGES})
139
140if(CMAKE_HOST_WIN32)
141    set(PYTHON_LIBRARY
142        "${PYTHON_PREFIX}/libs/Python${PYTHON_LIBRARY_SUFFIX}.lib")
143
144    # when run in a venv, PYTHON_PREFIX points to it. But the libraries remain in the
145    # original python installation. They may be found relative to PYTHON_INCLUDE_DIR.
146    if(NOT EXISTS "${PYTHON_LIBRARY}")
147        get_filename_component(_PYTHON_ROOT ${PYTHON_INCLUDE_DIR} DIRECTORY)
148        set(PYTHON_LIBRARY
149            "${_PYTHON_ROOT}/libs/Python${PYTHON_LIBRARY_SUFFIX}.lib")
150    endif()
151
152    # raise an error if the python libs are still not found.
153    if(NOT EXISTS "${PYTHON_LIBRARY}")
154        message(FATAL_ERROR "Python libraries not found")
155    endif()
156
157else()
158    if(PYTHON_MULTIARCH)
159        set(_PYTHON_LIBS_SEARCH "${PYTHON_LIBDIR}/${PYTHON_MULTIARCH}" "${PYTHON_LIBDIR}")
160    else()
161        set(_PYTHON_LIBS_SEARCH "${PYTHON_LIBDIR}")
162    endif()
163    #message(STATUS "Searching for Python libs in ${_PYTHON_LIBS_SEARCH}")
164    # Probably this needs to be more involved. It would be nice if the config
165    # information the python interpreter itself gave us were more complete.
166    find_library(PYTHON_LIBRARY
167        NAMES "python${PYTHON_LIBRARY_SUFFIX}"
168        PATHS ${_PYTHON_LIBS_SEARCH}
169        NO_DEFAULT_PATH)
170
171    # If all else fails, just set the name/version and let the linker figure out the path.
172    if(NOT PYTHON_LIBRARY)
173        set(PYTHON_LIBRARY python${PYTHON_LIBRARY_SUFFIX})
174    endif()
175endif()
176
177MARK_AS_ADVANCED(
178  PYTHON_LIBRARY
179  PYTHON_INCLUDE_DIR
180)
181
182# We use PYTHON_INCLUDE_DIR, PYTHON_LIBRARY and PYTHON_DEBUG_LIBRARY for the
183# cache entries because they are meant to specify the location of a single
184# library. We now set the variables listed by the documentation for this
185# module.
186SET(PYTHON_INCLUDE_DIRS "${PYTHON_INCLUDE_DIR}")
187SET(PYTHON_LIBRARIES "${PYTHON_LIBRARY}")
188SET(PYTHON_DEBUG_LIBRARIES "${PYTHON_DEBUG_LIBRARY}")
189
190find_package_message(PYTHON
191    "Found PythonLibs: ${PYTHON_LIBRARY}"
192    "${PYTHON_EXECUTABLE}${PYTHON_VERSION}")
193
194set(PYTHONLIBS_FOUND TRUE)
195