CMakeLists.txt revision 12391:ceeca8b41e4b 
1# CMakeLists.txt -- Build system for the pybind11 modules
2#
3# Copyright (c) 2015 Wenzel Jakob <wenzel@inf.ethz.ch>
4#
5# All rights reserved. Use of this source code is governed by a
6# BSD-style license that can be found in the LICENSE file.
7
8cmake_minimum_required(VERSION 2.8.12)
9
10if (POLICY CMP0048)
11  # cmake warns if loaded from a min-3.0-required parent dir, so silence the warning:
12  cmake_policy(SET CMP0048 NEW)
13endif()
14
15# CMake versions < 3.4.0 do not support try_compile/pthread checks without C as active language.
16if(CMAKE_VERSION VERSION_LESS 3.4.0)
17  project(pybind11)
18else()
19  project(pybind11 CXX)
20endif()
21
22# Check if pybind11 is being used directly or via add_subdirectory
23set(PYBIND11_MASTER_PROJECT OFF)
24if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
25  set(PYBIND11_MASTER_PROJECT ON)
26endif()
27
28option(PYBIND11_INSTALL "Install pybind11 header files?" ${PYBIND11_MASTER_PROJECT})
29option(PYBIND11_TEST    "Build pybind11 test suite?"     ${PYBIND11_MASTER_PROJECT})
30
31list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/tools")
32
33include(pybind11Tools)
34
35# Cache variables so pybind11_add_module can be used in parent projects
36set(PYBIND11_INCLUDE_DIR "${CMAKE_CURRENT_LIST_DIR}/include" CACHE INTERNAL "")
37set(PYTHON_INCLUDE_DIRS ${PYTHON_INCLUDE_DIRS} CACHE INTERNAL "")
38set(PYTHON_LIBRARIES ${PYTHON_LIBRARIES} CACHE INTERNAL "")
39set(PYTHON_MODULE_PREFIX ${PYTHON_MODULE_PREFIX} CACHE INTERNAL "")
40set(PYTHON_MODULE_EXTENSION ${PYTHON_MODULE_EXTENSION} CACHE INTERNAL "")
41
42# NB: when adding a header don't forget to also add it to setup.py
43set(PYBIND11_HEADERS
44  include/pybind11/detail/class.h
45  include/pybind11/detail/common.h
46  include/pybind11/detail/descr.h
47  include/pybind11/detail/init.h
48  include/pybind11/detail/internals.h
49  include/pybind11/detail/typeid.h
50  include/pybind11/attr.h
51  include/pybind11/buffer_info.h
52  include/pybind11/cast.h
53  include/pybind11/chrono.h
54  include/pybind11/common.h
55  include/pybind11/complex.h
56  include/pybind11/options.h
57  include/pybind11/eigen.h
58  include/pybind11/embed.h
59  include/pybind11/eval.h
60  include/pybind11/functional.h
61  include/pybind11/numpy.h
62  include/pybind11/operators.h
63  include/pybind11/pybind11.h
64  include/pybind11/pytypes.h
65  include/pybind11/stl.h
66  include/pybind11/stl_bind.h
67)
68string(REPLACE "include/" "${CMAKE_CURRENT_SOURCE_DIR}/include/"
69       PYBIND11_HEADERS "${PYBIND11_HEADERS}")
70
71if (PYBIND11_TEST)
72  add_subdirectory(tests)
73endif()
74
75include(GNUInstallDirs)
76include(CMakePackageConfigHelpers)
77
78# extract project version from source
79file(STRINGS "${PYBIND11_INCLUDE_DIR}/pybind11/detail/common.h" pybind11_version_defines
80     REGEX "#define PYBIND11_VERSION_(MAJOR|MINOR|PATCH) ")
81foreach(ver ${pybind11_version_defines})
82  if (ver MATCHES "#define PYBIND11_VERSION_(MAJOR|MINOR|PATCH) +([^ ]+)$")
83    set(PYBIND11_VERSION_${CMAKE_MATCH_1} "${CMAKE_MATCH_2}" CACHE INTERNAL "")
84  endif()
85endforeach()
86set(${PROJECT_NAME}_VERSION ${PYBIND11_VERSION_MAJOR}.${PYBIND11_VERSION_MINOR}.${PYBIND11_VERSION_PATCH})
87message(STATUS "pybind11 v${${PROJECT_NAME}_VERSION}")
88
89option (USE_PYTHON_INCLUDE_DIR "Install pybind11 headers in Python include directory instead of default installation prefix" OFF)
90if (USE_PYTHON_INCLUDE_DIR)
91    file(RELATIVE_PATH CMAKE_INSTALL_INCLUDEDIR ${CMAKE_INSTALL_PREFIX} ${PYTHON_INCLUDE_DIRS})
92endif()
93
94if(NOT (CMAKE_VERSION VERSION_LESS 3.0))  # CMake >= 3.0
95  # Build an interface library target:
96  add_library(pybind11 INTERFACE)
97  add_library(pybind11::pybind11 ALIAS pybind11)  # to match exported target
98  target_include_directories(pybind11 INTERFACE $<BUILD_INTERFACE:${PYBIND11_INCLUDE_DIR}>
99                                                $<BUILD_INTERFACE:${PYTHON_INCLUDE_DIRS}>
100                                                $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
101  target_compile_options(pybind11 INTERFACE $<BUILD_INTERFACE:${PYBIND11_CPP_STANDARD}>)
102
103  add_library(module INTERFACE)
104  add_library(pybind11::module ALIAS module)
105  if(NOT MSVC)
106    target_compile_options(module INTERFACE -fvisibility=hidden)
107  endif()
108  target_link_libraries(module INTERFACE pybind11::pybind11)
109  if(WIN32 OR CYGWIN)
110    target_link_libraries(module INTERFACE $<BUILD_INTERFACE:${PYTHON_LIBRARIES}>)
111  elseif(APPLE)
112    target_link_libraries(module INTERFACE "-undefined dynamic_lookup")
113  endif()
114
115  add_library(embed INTERFACE)
116  add_library(pybind11::embed ALIAS embed)
117  target_link_libraries(embed INTERFACE pybind11::pybind11 $<BUILD_INTERFACE:${PYTHON_LIBRARIES}>)
118endif()
119
120if (PYBIND11_INSTALL)
121  install(DIRECTORY ${PYBIND11_INCLUDE_DIR}/pybind11 DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
122  # GNUInstallDirs "DATADIR" wrong here; CMake search path wants "share".
123  set(PYBIND11_CMAKECONFIG_INSTALL_DIR "share/cmake/${PROJECT_NAME}" CACHE STRING "install path for pybind11Config.cmake")
124
125  configure_package_config_file(tools/${PROJECT_NAME}Config.cmake.in
126                                "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
127                                INSTALL_DESTINATION ${PYBIND11_CMAKECONFIG_INSTALL_DIR})
128  # Remove CMAKE_SIZEOF_VOID_P from ConfigVersion.cmake since the library does
129  # not depend on architecture specific settings or libraries.
130  set(_PYBIND11_CMAKE_SIZEOF_VOID_P ${CMAKE_SIZEOF_VOID_P})
131  unset(CMAKE_SIZEOF_VOID_P)
132  write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
133                                   VERSION ${${PROJECT_NAME}_VERSION}
134                                   COMPATIBILITY AnyNewerVersion)
135  set(CMAKE_SIZEOF_VOID_P ${_PYBIND11_CMAKE_SIZEOF_VOID_P})
136  install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
137                ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
138                tools/FindPythonLibsNew.cmake
139                tools/pybind11Tools.cmake
140          DESTINATION ${PYBIND11_CMAKECONFIG_INSTALL_DIR})
141
142  if(NOT (CMAKE_VERSION VERSION_LESS 3.0))
143    if(NOT PYBIND11_EXPORT_NAME)
144      set(PYBIND11_EXPORT_NAME "${PROJECT_NAME}Targets")
145    endif()
146
147    install(TARGETS pybind11 module embed
148            EXPORT "${PYBIND11_EXPORT_NAME}")
149    if(PYBIND11_MASTER_PROJECT)
150      install(EXPORT "${PYBIND11_EXPORT_NAME}"
151              NAMESPACE "${PROJECT_NAME}::"
152              DESTINATION ${PYBIND11_CMAKECONFIG_INSTALL_DIR})
153    endif()
154  endif()
155endif()
156