SConstruct revision 1963 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29###################################################
30#
31# SCons top-level build description (SConstruct) file.
32#
33# To build M5, you need a directory with three things:
34# 1. A copy of this file (named SConstruct).
35# 2. A link named 'm5' to the top of the M5 simulator source tree.
36# 3. A link named 'ext' to the top of the M5 external source tree.
37#
38# Then type 'scons' to build the default configuration (see below), or
39# 'scons <CONFIG>/<binary>' to build some other configuration (e.g.,
40# 'ALPHA_FS/m5.opt' for the optimized full-system version).
41#
42###################################################
43
44# Python library imports
45import sys
46import os
47
48# Check for recent-enough Python and SCons versions
49EnsurePythonVersion(2,3)
50EnsureSConsVersion(0,96)
51
52# The absolute path to the current directory (where this file lives).
53ROOT = Dir('.').abspath
54
55# Paths to the M5 and external source trees (local symlinks).
56SRCDIR = os.path.join(ROOT, 'm5')
57EXT_SRCDIR = os.path.join(ROOT, 'ext')
58
59# Check for 'm5' and 'ext' links, die if they don't exist.
60if not os.path.isdir(SRCDIR):
61    print "Error: '%s' must be a link to the M5 source tree." % SRCDIR
62    Exit(1)
63
64if not os.path.isdir('ext'):
65    print "Error: '%s' must be a link to the M5 external source tree." \
66          % EXT_SRCDIR
67    Exit(1)
68
69# tell python where to find m5 python code
70sys.path.append(os.path.join(SRCDIR, 'python'))
71
72###################################################
73#
74# Figure out which configurations to set up.
75#
76#
77# It's prohibitive to do all the combinations of base configurations
78# and options, so we have to infer which ones the user wants.
79#
80# 1. If there are command-line targets, the configuration(s) are inferred
81#    from the directories of those targets.  If scons was invoked from a
82#    subdirectory (using 'scons -u'), those targets have to be
83#    interpreted relative to that subdirectory.
84#
85# 2. If there are no command-line targets, and scons was invoked from a
86#    subdirectory (using 'scons -u'), the configuration is inferred from
87#    the name of the subdirectory.
88#
89# 3. If there are no command-line targets and scons was invoked from
90#    the root build directory, a default configuration is used.  The
91#    built-in default is ALPHA_SE, but this can be overridden by setting the
92#    M5_DEFAULT_CONFIG shell environment veriable.
93#
94# In cases 2 & 3, the specific file target defaults to 'm5.debug', but
95# this can be overridden by setting the M5_DEFAULT_BINARY shell
96# environment veriable.
97#
98###################################################
99
100# Find default configuration & binary.
101default_config = os.environ.get('M5_DEFAULT_CONFIG', 'ALPHA_SE')
102default_binary = os.environ.get('M5_DEFAULT_BINARY', 'm5.debug')
103
104# Ask SCons which directory it was invoked from.  If you invoke SCons
105# from a subdirectory you must use the '-u' flag.
106launch_dir = GetLaunchDir()
107
108# Build a list 'my_targets' of all the targets relative to ROOT.
109if launch_dir == ROOT:
110    # invoked from root build dir
111    if len(COMMAND_LINE_TARGETS) != 0:
112        # easy: use specified targets as is
113        my_targets = COMMAND_LINE_TARGETS
114    else:
115        # default target (ALPHA_SE/m5.debug, unless overridden)
116        target = os.path.join(default_config, default_binary)
117        my_targets = [target]
118        Default(target)
119else:
120    # invoked from subdirectory
121    if not launch_dir.startswith(ROOT):
122        print "Error: launch dir (%s) not a subdirectory of ROOT (%s)!" \
123              (launch_dir, ROOT)
124        Exit(1)
125    # make launch_dir relative to ROOT (strip ROOT plus slash off front)
126    launch_dir = launch_dir[len(ROOT)+1:]
127    if len(COMMAND_LINE_TARGETS) != 0:
128        # make specified targets relative to ROOT
129        my_targets = map(lambda x: os.path.join(launch_dir, x),
130                         COMMAND_LINE_TARGETS)
131    else:
132        # build default binary (m5.debug, unless overridden) using the
133        # config inferred by the invocation directory (the first
134        # subdirectory after ROOT)
135        target = os.path.join(launch_dir.split('/')[0], default_binary)
136        my_targets = [target]
137        Default(target)
138
139# Normalize target paths (gets rid of '..' in the middle, etc.)
140my_targets = map(os.path.normpath, my_targets)
141
142# Generate a list of the unique configs that the collected targets reference.
143build_dirs = []
144for t in my_targets:
145    dir = t.split('/')[0]
146    if dir not in build_dirs:
147        build_dirs.append(dir)
148
149###################################################
150#
151# Set up the default build environment.  This environment is copied
152# and modified according to each selected configuration.
153#
154###################################################
155
156env = Environment(ENV = os.environ,  # inherit user's environment vars
157                  ROOT = ROOT,
158                  SRCDIR = SRCDIR,
159                  EXT_SRCDIR = EXT_SRCDIR)
160
161env.SConsignFile("sconsign")
162
163# I waffle on this setting... it does avoid a few painful but
164# unnecessary builds, but it also seems to make trivial builds take
165# noticeably longer.
166if False:
167    env.TargetSignatures('content')
168
169# M5_EXT is used by isa_parser.py to find the PLY package.
170env.Append(ENV = { 'M5_EXT' : EXT_SRCDIR })
171
172# Set up default C++ compiler flags
173env.Append(CCFLAGS='-pipe')
174env.Append(CCFLAGS='-fno-strict-aliasing')
175env.Append(CCFLAGS=Split('-Wall -Wno-sign-compare -Werror -Wundef'))
176if sys.platform == 'cygwin':
177    # cygwin has some header file issues...
178    env.Append(CCFLAGS=Split("-Wno-uninitialized"))
179env.Append(CPPPATH=[os.path.join(EXT_SRCDIR + '/dnet')])
180
181# Default libraries
182env.Append(LIBS=['z'])
183
184# Platform-specific configuration
185conf = Configure(env)
186
187# Check for <fenv.h> (C99 FP environment control)
188have_fenv = conf.CheckHeader('fenv.h', '<>')
189if not have_fenv:
190    print "Warning: Header file <fenv.h> not found."
191    print "         This host has no IEEE FP rounding mode control."
192
193# Check for mysql.
194mysql_config = WhereIs('mysql_config')
195have_mysql = mysql_config != None
196
197# Check MySQL version.
198if have_mysql:
199    mysql_version = os.popen(mysql_config + ' --version').read()
200    mysql_version = mysql_version.split('.')
201    mysql_major = int(mysql_version[0])
202    mysql_minor = int(mysql_version[1])
203    # This version check is probably overly conservative, but it deals
204    # with the versions we have installed.
205    if mysql_major < 4 or (mysql_major == 4 and mysql_minor < 1):
206        print "Warning: MySQL v4.1 or newer required."
207        have_mysql = False
208
209# Set up mysql_config commands.
210if have_mysql:
211    mysql_config_include = mysql_config + ' --include'
212    if os.system(mysql_config_include + ' > /dev/null') != 0:
213        # older mysql_config versions don't support --include, use
214        # --cflags instead
215        mysql_config_include = mysql_config + ' --cflags | sed s/\\\'//g'
216    # This seems to work in all versions
217    mysql_config_libs = mysql_config + ' --libs'
218
219env = conf.Finish()
220
221# Sticky options get saved in the options file so they persist from
222# one invocation to the next (unless overridden, in which case the new
223# value becomes sticky).
224sticky_opts = Options(args=ARGUMENTS)
225sticky_opts.AddOptions(
226    EnumOption('TARGET_ISA', 'Target ISA', 'alpha', ('alpha')),
227    BoolOption('FULL_SYSTEM', 'Full-system support', False),
228    BoolOption('ALPHA_TLASER',
229               'Model Alpha TurboLaser platform (vs. Tsunami)', False),
230    BoolOption('NO_FAST_ALLOC', 'Disable fast object allocator', False),
231    BoolOption('EFENCE', 'Link with Electric Fence malloc debugger',
232               False),
233    BoolOption('SS_COMPATIBLE_FP',
234               'Make floating-point results compatible with SimpleScalar',
235               False),
236    BoolOption('STATS_BINNING', 'Bin statistics by CPU mode', have_mysql),
237    BoolOption('USE_MYSQL', 'Use MySQL for stats output', have_mysql),
238    BoolOption('USE_FENV', 'Use <fenv.h> IEEE mode control', have_fenv),
239    ('CC', 'C compiler', os.environ.get('CC', env['CC'])),
240    ('CXX', 'C++ compiler', os.environ.get('CXX', env['CXX'])),
241    BoolOption('BATCH', 'Use batch pool for build and tests', False),
242    ('BATCH_CMD', 'Batch pool submission command name', 'qdo')
243    )
244
245# Non-sticky options only apply to the current build.
246nonsticky_opts = Options(args=ARGUMENTS)
247nonsticky_opts.AddOptions(
248    BoolOption('update_ref', 'Update test reference outputs', False)
249    )
250
251# These options get exported to #defines in config/*.hh (see m5/SConscript).
252env.ExportOptions = ['FULL_SYSTEM', 'ALPHA_TLASER', 'USE_FENV', \
253                     'USE_MYSQL', 'NO_FAST_ALLOC', 'SS_COMPATIBLE_FP', \
254                     'STATS_BINNING']
255
256# Define a handy 'no-op' action
257def no_action(target, source, env):
258    return 0
259
260env.NoAction = Action(no_action, None)
261
262# libelf build is described in its own SConscript file.
263# SConscript-global is the build in build/libelf shared among all
264# configs.
265env.SConscript('m5/libelf/SConscript-global', exports = 'env')
266
267###################################################
268#
269# Define a SCons builder for configuration flag headers.
270#
271###################################################
272
273# This function generates a config header file that #defines the
274# option symbol to the current option setting (0 or 1).  The source
275# operands are the name of the option and a Value node containing the
276# value of the option.
277def build_config_file(target, source, env):
278    (option, value) = [s.get_contents() for s in source]
279    f = file(str(target[0]), 'w')
280    print >> f, '#define', option, value
281    f.close()
282    return None
283
284# Generate the message to be printed when building the config file.
285def build_config_file_string(target, source, env):
286    (option, value) = [s.get_contents() for s in source]
287    return "Defining %s as %s in %s." % (option, value, target[0])
288
289# Combine the two functions into a scons Action object.
290config_action = Action(build_config_file, build_config_file_string)
291
292# The emitter munges the source & target node lists to reflect what
293# we're really doing.
294def config_emitter(target, source, env):
295    # extract option name from Builder arg
296    option = str(target[0])
297    # True target is config header file
298    target = os.path.join('config', option.lower() + '.hh')
299    # Force value to 0/1 even if it's a Python bool
300    val = int(eval(str(env[option])))
301    # Sources are option name & value (packaged in SCons Value nodes)
302    return ([target], [Value(option), Value(val)])
303
304config_builder = Builder(emitter = config_emitter, action = config_action)
305
306env.Append(BUILDERS = { 'ConfigFile' : config_builder })
307
308###################################################
309#
310# Define build environments for selected configurations.
311#
312###################################################
313
314# rename base env
315base_env = env
316
317for build_dir in build_dirs:
318    # Make a copy of the default environment to use for this config.
319    env = base_env.Copy()
320    # Set env according to the build directory config.
321
322    sticky_opts.files = []
323    # Name of default options file is taken from 'default=' on command
324    # line if set, otherwise name of build dir.
325    default_options_file = os.path.join('build_options', 'default',
326                                        ARGUMENTS.get('default', build_dir))
327    if os.path.isfile(default_options_file):
328        sticky_opts.files.append(default_options_file)
329    current_options_file = os.path.join('build_options', 'current', build_dir)
330    if os.path.isfile(current_options_file):
331        sticky_opts.files.append(current_options_file)
332    else:
333        # if file doesn't exist, make sure at least the directory is there
334        # so we can create it later
335        opt_dir = os.path.dirname(current_options_file)
336        if not os.path.isdir(opt_dir):
337            os.mkdir(opt_dir)
338    if not sticky_opts.files:
339        print "%s: No options file found in build_options, using defaults." \
340              % build_dir
341
342    # Apply current option settings to env
343    sticky_opts.Update(env)
344    nonsticky_opts.Update(env)
345
346    # Process option settings.
347
348    if not have_fenv and env['USE_FENV']:
349        print "Warning: <fenv.h> not available; " \
350              "forcing USE_FENV to False in", build_dir + "."
351        env['USE_FENV'] = False
352
353    if not env['USE_FENV']:
354        print "Warning: No IEEE FP rounding mode control in", build_dir + "."
355        print "         FP results may deviate slightly from other platforms."
356
357    if env['EFENCE']:
358        env.Append(LIBS=['efence'])
359
360    if env['USE_MYSQL']:
361        if not have_mysql:
362            print "Warning: MySQL not available; " \
363                  "forcing USE_MYSQL to False in", build_dir + "."
364            env['USE_MYSQL'] = False
365        else:
366            print "Compiling in", build_dir, "with MySQL support."
367            env.ParseConfig(mysql_config_libs)
368            env.ParseConfig(mysql_config_include)
369
370    # Save sticky option settings back to current options file
371    sticky_opts.Save(current_options_file, env)
372
373    # Do this after we save setting back, or else we'll tack on an
374    # extra 'qdo' every time we run scons.
375    if env['BATCH']:
376        env['CC']  = env['BATCH_CMD'] + ' ' + env['CC']
377        env['CXX'] = env['BATCH_CMD'] + ' ' + env['CXX']
378
379    # The m5/SConscript file sets up the build rules in 'env' according
380    # to the configured options.  It returns a list of environments,
381    # one for each variant build (debug, opt, etc.)
382    envList = SConscript('m5/SConscript', build_dir = build_dir,
383                         exports = 'env', duplicate = False)
384
385    # Set up the regression tests for each build.
386    for e in envList:
387        SConscript('m5-test/SConscript',
388                   build_dir = os.path.join(build_dir, 'test', e.Label),
389                   exports = { 'env' : e }, duplicate = False)
390
391###################################################
392#
393# Let SCons do its thing.  At this point SCons will use the defined
394# build environments to build the requested targets.
395#
396###################################################
397
398