SConscript revision 11308 
1# -*- mode:python -*-
2
3# Copyright (c) 2006 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28#
29# Authors: Steve Reinhardt
30
31import sys
32import os
33import re
34
35Import('*')
36
37#################################################################
38#
39# ISA "switch header" generation.
40#
41# Auto-generate arch headers that include the right ISA-specific
42# header based on the setting of THE_ISA preprocessor variable.
43#
44#################################################################
45
46# List of headers to generate
47isa_switch_hdrs = Split('''
48        decoder.hh
49        interrupts.hh
50        isa.hh
51        isa_traits.hh
52        kernel_stats.hh
53        locked_mem.hh
54        microcode_rom.hh
55        mmapped_ipr.hh
56        mt.hh
57        process.hh
58        pseudo_inst.hh
59        registers.hh
60        remote_gdb.hh
61        stacktrace.hh
62        tlb.hh
63        types.hh
64        utility.hh
65        vtophys.hh
66        ''')
67
68# Set up this directory to support switching headers
69make_switching_dir('arch', isa_switch_hdrs, env)
70
71if env['BUILD_GPU']:
72    gpu_isa_switch_hdrs = Split('''
73            gpu_decoder.hh
74            gpu_types.hh
75            ''')
76
77    make_gpu_switching_dir('arch', gpu_isa_switch_hdrs, env)
78
79#################################################################
80#
81# Include architecture-specific files.
82#
83#################################################################
84
85#
86# Build a SCons scanner for ISA files
87#
88import SCons.Scanner
89
90isa_scanner = SCons.Scanner.Classic("ISAScan",
91                                    [".isa", ".ISA"],
92                                    "SRCDIR",
93                                    r'^\s*##include\s+"([\w/.-]*)"')
94
95env.Append(SCANNERS = isa_scanner)
96
97#
98# Now create a Builder object that uses isa_parser.py to generate C++
99# output from the ISA description (*.isa) files.
100#
101
102isa_parser = File('isa_parser.py')
103
104# The emitter patches up the sources & targets to include the
105# autogenerated files as targets and isa parser itself as a source.
106def isa_desc_emitter(target, source, env):
107    # List the isa parser as a source.
108    source += [
109        isa_parser,
110        Value("ExecContext"),
111        ]
112
113    # Specify different targets depending on if we're running the ISA
114    # parser for its dependency information, or for the generated files.
115    # (As an optimization, the ISA parser detects the useless second run
116    # and skips doing any work, if the first run was performed, since it
117    # always generates all its files). The way we track this in SCons is the
118    # <arch>_isa_outputs value in the environment (env). If it's unset, we
119    # don't know what the dependencies are so we ask for generated/inc.d to
120    # be generated so they can be acquired. If we know what they are, then
121    # it's because we've already processed inc.d and then claim that our
122    # outputs (targets) will be thus.
123    isa = env['TARGET_ISA']
124    key = '%s_isa_outputs' % isa
125    if key in env:
126        targets = [ os.path.join('generated', f) for f in env[key] ]
127    else:
128        targets = [ os.path.join('generated','inc.d') ]
129
130    def prefix(s):
131        return os.path.join(target[0].dir.up().abspath, s)
132
133    return [ prefix(t) for t in targets ], source
134
135ARCH_DIR = Dir('.')
136
137# import ply here because SCons screws with sys.path when performing actions.
138import ply
139
140def isa_desc_action_func(target, source, env):
141    # Add the current directory to the system path so we can import files
142    sys.path[0:0] = [ ARCH_DIR.srcnode().abspath ]
143    import isa_parser
144
145    # Skip over the ISA description itself and the parser to the CPU models.
146    models = [ s.get_contents() for s in source[2:] ]
147    parser = isa_parser.ISAParser(target[0].dir.abspath)
148    parser.parse_isa_desc(source[0].abspath)
149isa_desc_action = MakeAction(isa_desc_action_func, Transform("ISA DESC", 1))
150
151# Also include the CheckerCPU as one of the models if it is being
152# enabled via command line.
153isa_desc_builder = Builder(action=isa_desc_action, emitter=isa_desc_emitter)
154
155env.Append(BUILDERS = { 'ISADesc' : isa_desc_builder })
156
157# The ISA is generated twice: the first time to find out what it generates,
158# and the second time to make scons happy by telling the ISADesc builder
159# what it will make before it builds it.
160def scan_isa_deps(target, source, env):
161    # Process dependency file generated by the ISA parser --
162    # add the listed files to the dependency tree of the build.
163    source = source[0]
164    archbase = source.dir.up().path
165
166    try:
167        depfile = open(source.abspath, 'r')
168    except:
169        print "scan_isa_deps: Can't open ISA deps file '%s' in %s" % \
170              (source.path,os.getcwd())
171        raise
172
173    # Scan through the lines
174    targets = {}
175    for line in depfile:
176        # Read the dependency line with the format
177        # <target file>: [ <dependent file>* ]
178        m = re.match(r'^\s*([^:]+\.([^\.:]+))\s*:\s*(.*)', line)
179        assert(m)
180        targ, extn = m.group(1,2)
181        deps = m.group(3).split()
182
183        files = [ targ ] + deps
184        for f in files:
185            targets[f] = True
186            # Eliminate unnecessary re-generation if we already generated it
187            env.Precious(os.path.join(archbase, 'generated', f))
188
189        files = [ os.path.join(archbase, 'generated', f) for f in files ]
190
191        if extn == 'cc':
192            Source(os.path.join(archbase,'generated', targ))
193    depfile.close()
194    env[env['TARGET_ISA'] + '_isa_outputs'] = targets.keys()
195
196    isa = env.ISADesc(os.path.join(archbase,'isa','main.isa'))
197    for t in targets:
198        env.Depends('#all-isas', isa)
199
200env.Append(BUILDERS = {'ScanISA' :
201                        Builder(action=MakeAction(scan_isa_deps,
202                                                  Transform("NEW DEPS", 1)))})
203
204DebugFlag('IntRegs')
205DebugFlag('FloatRegs')
206DebugFlag('CCRegs')
207DebugFlag('MiscRegs')
208CompoundFlag('Registers', [ 'IntRegs', 'FloatRegs', 'CCRegs', 'MiscRegs' ])
209