SConscript revision 3981:418c4e51644a 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28#
29# Authors: Steve Reinhardt
30
31import os
32import sys
33from os.path import isfile, join as joinpath
34
35# This file defines how to build a particular configuration of M5
36# based on variable settings in the 'env' build environment.
37
38# Import build environment variable from SConstruct.
39Import('env')
40
41###################################################
42#
43# Define needed sources.
44#
45###################################################
46
47# Base sources used by all configurations.
48
49base_sources = Split('''
50	base/annotate.cc
51	base/circlebuf.cc
52	base/cprintf.cc
53	base/fast_alloc.cc
54	base/fifo_buffer.cc
55	base/hostinfo.cc
56	base/hybrid_pred.cc
57	base/inifile.cc
58	base/intmath.cc
59	base/match.cc
60	base/misc.cc
61	base/output.cc
62	base/pollevent.cc
63	base/range.cc
64	base/random.cc
65	base/remote_gdb.cc
66	base/sat_counter.cc
67	base/socket.cc
68	base/statistics.cc
69	base/str.cc
70	base/time.cc
71	base/trace.cc
72	base/traceflags.cc
73	base/userinfo.cc
74	base/compression/lzss_compression.cc
75	base/loader/aout_object.cc
76	base/loader/ecoff_object.cc
77	base/loader/elf_object.cc
78	base/loader/raw_object.cc
79	base/loader/object_file.cc
80	base/loader/symtab.cc
81	base/stats/events.cc
82	base/stats/statdb.cc
83	base/stats/visit.cc
84	base/stats/text.cc
85
86        cpu/activity.cc
87	cpu/base.cc
88	cpu/cpuevent.cc
89	cpu/exetrace.cc
90        cpu/func_unit.cc
91        cpu/op_class.cc
92	cpu/pc_event.cc
93        cpu/quiesce_event.cc
94	cpu/static_inst.cc
95        cpu/simple_thread.cc
96        cpu/thread_state.cc
97
98        mem/bridge.cc
99        mem/bus.cc
100        mem/dram.cc
101        mem/mem_object.cc
102        mem/packet.cc
103        mem/physical.cc
104        mem/port.cc
105        mem/tport.cc
106
107        mem/cache/base_cache.cc
108        mem/cache/cache.cc
109        mem/cache/coherence/coherence_protocol.cc
110        mem/cache/coherence/uni_coherence.cc
111        mem/cache/miss/blocking_buffer.cc
112        mem/cache/miss/miss_buffer.cc
113        mem/cache/miss/miss_queue.cc
114        mem/cache/miss/mshr.cc
115        mem/cache/miss/mshr_queue.cc
116        mem/cache/prefetch/base_prefetcher.cc
117        mem/cache/prefetch/ghb_prefetcher.cc
118        mem/cache/prefetch/stride_prefetcher.cc
119        mem/cache/prefetch/tagged_prefetcher.cc
120        mem/cache/tags/base_tags.cc
121        mem/cache/tags/fa_lru.cc
122        mem/cache/tags/iic.cc
123        mem/cache/tags/lru.cc
124        mem/cache/tags/repl/gen.cc
125        mem/cache/tags/repl/repl.cc
126        mem/cache/tags/split.cc
127        mem/cache/tags/split_lifo.cc
128        mem/cache/tags/split_lru.cc
129
130        mem/cache/cache_builder.cc
131
132        python/swig/init.cc
133        python/swig/debug_wrap.cc
134        python/swig/main_wrap.cc
135        python/swig/event_wrap.cc
136        python/swig/pyevent.cc
137
138	sim/builder.cc
139	sim/debug.cc
140	sim/eventq.cc
141	sim/faults.cc
142	sim/main.cc
143	sim/param.cc
144	sim/root.cc
145	sim/serialize.cc
146	sim/sim_events.cc
147	sim/sim_object.cc
148	sim/startup.cc
149	sim/stat_context.cc
150	sim/stat_control.cc
151	sim/system.cc
152	sim/trace_context.cc
153        ''')
154
155trace_reader_sources = Split('''
156        cpu/trace/reader/mem_trace_reader.cc
157        cpu/trace/reader/ibm_reader.cc
158        cpu/trace/reader/itx_reader.cc
159        cpu/trace/reader/m5_reader.cc
160        cpu/trace/opt_cpu.cc
161        cpu/trace/trace_cpu.cc
162        ''')
163
164
165
166# MySql sources
167mysql_sources = Split('''
168	base/mysql.cc
169	base/stats/mysql.cc
170        ''')
171
172# Full-system sources
173full_system_sources = Split('''
174	base/crc.cc
175	base/inet.cc
176
177	cpu/intr_control.cc
178        cpu/profile.cc
179
180	dev/uart.cc
181	dev/uart8250.cc
182
183        mem/vport.cc
184
185	sim/pseudo_inst.cc
186        ''')
187	#dev/sinic.cc
188        #dev/i8254xGBe.cc
189
190if env['TARGET_ISA'] == 'alpha':
191    full_system_sources += Split('''
192	kern/tru64/dump_mbuf.cc
193	kern/tru64/printf.cc
194	kern/tru64/tru64_events.cc
195	kern/tru64/tru64_syscalls.cc
196        ''')
197
198# Syscall emulation (non-full-system) sources
199syscall_emulation_sources = Split('''
200        mem/translating_port.cc
201        mem/page_table.cc
202	sim/process.cc
203	sim/syscall_emul.cc
204        ''')
205
206#if env['TARGET_ISA'] == 'alpha':
207#    syscall_emulation_sources += Split('''
208#        kern/tru64/tru64.cc
209#        ''')
210
211memtest_sources = Split('''
212	cpu/memtest/memtest.cc
213        ''')
214
215# Include file paths are rooted in this directory.  SCons will
216# automatically expand '.' to refer to both the source directory and
217# the corresponding build directory to pick up generated include
218# files.
219env.Append(CPPPATH=Dir('.'))
220
221# Add a flag defining what THE_ISA should be for all compilation
222env.Append(CPPDEFINES=[('THE_ISA','%s_ISA' % env['TARGET_ISA'].upper())])
223
224arch_sources = SConscript(os.path.join('arch', 'SConscript'), exports = 'env')
225
226cpu_sources = SConscript(os.path.join('cpu', 'SConscript'), exports = 'env')
227
228if env['FULL_SYSTEM']:
229    dev_sources = SConscript(os.path.join('dev', 'SConscript'),
230                             exports = 'env')
231    full_system_sources += dev_sources
232
233    kern_sources = SConscript(os.path.join('kern', 'SConscript'),
234                              exports = 'env')
235    full_system_sources += kern_sources
236
237# Set up complete list of sources based on configuration.
238sources = base_sources + arch_sources + cpu_sources
239
240# encumbered should be last because we're adding to some of the other groups
241if isfile(joinpath(env['SRCDIR'], 'encumbered/SConscript')):
242    sources += SConscript('encumbered/SConscript', exports = 'env')
243
244
245if env['FULL_SYSTEM']:
246    sources += full_system_sources
247else:
248    sources += syscall_emulation_sources
249
250if env['USE_MYSQL']:
251    sources += mysql_sources
252
253for opt in env.ExportOptions:
254    env.ConfigFile(opt)
255
256###################################################
257#
258# Special build rules.
259#
260###################################################
261
262# base/traceflags.{cc,hh} are generated from base/traceflags.py.
263# $TARGET.base will expand to "<build-dir>/base/traceflags".
264env.Command(Split('base/traceflags.hh base/traceflags.cc'),
265            'base/traceflags.py',
266            'python $SOURCE $TARGET.base')
267
268SConscript('python/SConscript', exports = ['env'])
269
270# This function adds the specified sources to the given build
271# environment, and returns a list of all the corresponding SCons
272# Object nodes (including an extra one for date.cc).  We explicitly
273# add the Object nodes so we can set up special dependencies for
274# date.cc.
275def make_objs(sources, env):
276    objs = [env.Object(s) for s in sources]
277    # make date.cc depend on all other objects so it always gets
278    # recompiled whenever anything else does
279    date_obj = env.Object('base/date.cc')
280    env.Depends(date_obj, objs)
281    objs.append(date_obj)
282    return objs
283
284###################################################
285#
286# Define binaries.  Each different build type (debug, opt, etc.) gets
287# a slightly different build environment.
288#
289###################################################
290
291# List of constructed environments to pass back to SConstruct
292envList = []
293
294# Function to create a new build environment as clone of current
295# environment 'env' with modified object suffix and optional stripped
296# binary.  Additional keyword arguments are appended to corresponding
297# build environment vars.
298def makeEnv(label, objsfx, strip = False, **kwargs):
299    newEnv = env.Copy(OBJSUFFIX=objsfx)
300    newEnv.Label = label
301    newEnv.Append(**kwargs)
302    exe = 'm5.' + label  # final executable
303    bin = exe + '.bin'   # executable w/o appended Python zip archive
304    newEnv.Program(bin, make_objs(sources, newEnv))
305    if strip:
306        stripped_bin = bin + '.stripped'
307        newEnv.Command(stripped_bin, bin, 'strip $SOURCE -o $TARGET')
308        bin = stripped_bin
309    targets = newEnv.Concat(exe, [bin, 'python/m5py.zip'])
310    newEnv.M5Binary = targets[0]
311    envList.append(newEnv)
312
313# Debug binary
314ccflags = {}
315if env['GCC']:
316    if sys.platform == 'sunos5':
317        ccflags['debug'] = '-gstabs+'
318    else:
319        ccflags['debug'] = '-ggdb3'
320    ccflags['opt'] = '-g -O3'
321    ccflags['fast'] = '-O3'
322    ccflags['prof'] = '-O3 -g -pg'
323elif env['SUNCC']:
324    ccflags['debug'] = '-g0'
325    ccflags['opt'] = '-g -O'
326    ccflags['fast'] = '-fast'
327    ccflags['prof'] = '-fast -g -pg'
328elif env['ICC']:
329    ccflags['debug'] = '-g -O0'
330    ccflags['opt'] = '-g -O'
331    ccflags['fast'] = '-fast'
332    ccflags['prof'] = '-fast -g -pg'
333else:
334    print 'Unknown compiler, please fix compiler options'
335    Exit(1)    
336
337makeEnv('debug', '.do',
338        CCFLAGS = Split(ccflags['debug']),
339        CPPDEFINES = ['DEBUG', 'TRACING_ON=1'])
340
341# Optimized binary
342makeEnv('opt', '.o',
343        CCFLAGS = Split(ccflags['opt']),
344        CPPDEFINES = ['TRACING_ON=1'])
345
346# "Fast" binary
347makeEnv('fast', '.fo', strip = True,
348        CCFLAGS = Split(ccflags['fast']),
349        CPPDEFINES = ['NDEBUG', 'TRACING_ON=0'])
350
351# Profiled binary
352makeEnv('prof', '.po',
353        CCFLAGS = Split(ccflags['prof']),
354        CPPDEFINES = ['NDEBUG', 'TRACING_ON=0'],
355        LINKFLAGS = '-pg')
356
357Return('envList')
358