SConscript revision 3624 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28#
29# Authors: Steve Reinhardt
30
31import os
32import sys
33from os.path import isfile, join as joinpath
34
35# This file defines how to build a particular configuration of M5
36# based on variable settings in the 'env' build environment.
37
38# Import build environment variable from SConstruct.
39Import('env')
40
41###################################################
42#
43# Define needed sources.
44#
45###################################################
46
47# Base sources used by all configurations.
48
49base_sources = Split('''
50	base/annotate.cc
51	base/circlebuf.cc
52	base/cprintf.cc
53	base/fast_alloc.cc
54	base/fifo_buffer.cc
55	base/hostinfo.cc
56	base/hybrid_pred.cc
57	base/inifile.cc
58	base/intmath.cc
59	base/match.cc
60	base/misc.cc
61	base/output.cc
62	base/pollevent.cc
63	base/range.cc
64	base/random.cc
65	base/sat_counter.cc
66	base/socket.cc
67	base/statistics.cc
68	base/str.cc
69	base/time.cc
70	base/trace.cc
71	base/traceflags.cc
72	base/userinfo.cc
73	base/compression/lzss_compression.cc
74	base/loader/aout_object.cc
75	base/loader/ecoff_object.cc
76	base/loader/elf_object.cc
77	base/loader/raw_object.cc
78	base/loader/object_file.cc
79	base/loader/symtab.cc
80	base/stats/events.cc
81	base/stats/statdb.cc
82	base/stats/visit.cc
83	base/stats/text.cc
84
85        cpu/activity.cc
86	cpu/base.cc
87	cpu/cpuevent.cc
88	cpu/exetrace.cc
89        cpu/func_unit.cc
90        cpu/op_class.cc
91	cpu/pc_event.cc
92        cpu/quiesce_event.cc
93	cpu/static_inst.cc
94        cpu/simple_thread.cc
95        cpu/thread_state.cc
96
97        mem/bridge.cc
98        mem/bus.cc
99        mem/dram.cc
100        mem/mem_object.cc
101        mem/packet.cc
102        mem/physical.cc
103        mem/port.cc
104        mem/tport.cc
105
106        mem/cache/base_cache.cc
107        mem/cache/cache.cc
108        mem/cache/coherence/coherence_protocol.cc
109        mem/cache/coherence/uni_coherence.cc
110        mem/cache/miss/blocking_buffer.cc
111        mem/cache/miss/miss_queue.cc
112        mem/cache/miss/mshr.cc
113        mem/cache/miss/mshr_queue.cc
114        mem/cache/prefetch/base_prefetcher.cc
115        mem/cache/prefetch/ghb_prefetcher.cc
116        mem/cache/prefetch/prefetcher.cc
117        mem/cache/prefetch/stride_prefetcher.cc
118        mem/cache/prefetch/tagged_prefetcher.cc
119        mem/cache/tags/base_tags.cc
120        mem/cache/tags/cache_tags.cc
121        mem/cache/tags/fa_lru.cc
122        mem/cache/tags/iic.cc
123        mem/cache/tags/lru.cc
124        mem/cache/tags/repl/gen.cc
125        mem/cache/tags/repl/repl.cc
126        mem/cache/tags/split.cc
127        mem/cache/tags/split_lifo.cc
128        mem/cache/tags/split_lru.cc
129
130        mem/cache/cache_builder.cc
131
132        python/swig/main_wrap.cc
133
134	sim/builder.cc
135	sim/debug.cc
136	sim/eventq.cc
137	sim/faults.cc
138	sim/main.cc
139	sim/param.cc
140	sim/root.cc
141	sim/serialize.cc
142	sim/sim_events.cc
143	sim/sim_object.cc
144	sim/startup.cc
145	sim/stat_context.cc
146	sim/stat_control.cc
147	sim/system.cc
148	sim/trace_context.cc
149        ''')
150
151trace_reader_sources = Split('''
152        cpu/trace/reader/mem_trace_reader.cc
153        cpu/trace/reader/ibm_reader.cc
154        cpu/trace/reader/itx_reader.cc
155        cpu/trace/reader/m5_reader.cc
156        cpu/trace/opt_cpu.cc
157        cpu/trace/trace_cpu.cc
158        ''')
159
160
161
162# MySql sources
163mysql_sources = Split('''
164	base/mysql.cc
165	base/stats/mysql.cc
166        ''')
167
168# Full-system sources
169full_system_sources = Split('''
170	base/crc.cc
171	base/inet.cc
172	base/remote_gdb.cc
173
174	cpu/intr_control.cc
175        cpu/profile.cc
176
177	dev/uart.cc
178	dev/uart8250.cc
179
180        mem/vport.cc
181
182	sim/pseudo_inst.cc
183        ''')
184	#dev/sinic.cc
185        #dev/i8254xGBe.cc
186
187if env['TARGET_ISA'] == 'alpha':
188    full_system_sources += Split('''
189	kern/tru64/dump_mbuf.cc
190	kern/tru64/printf.cc
191	kern/tru64/tru64_events.cc
192	kern/tru64/tru64_syscalls.cc
193        ''')
194
195# Syscall emulation (non-full-system) sources
196syscall_emulation_sources = Split('''
197        mem/translating_port.cc
198        mem/page_table.cc
199	sim/process.cc
200	sim/syscall_emul.cc
201        ''')
202
203#if env['TARGET_ISA'] == 'alpha':
204#    syscall_emulation_sources += Split('''
205#        kern/tru64/tru64.cc
206#        ''')
207
208memtest_sources = Split('''
209	cpu/memtest/memtest.cc
210        ''')
211
212# Include file paths are rooted in this directory.  SCons will
213# automatically expand '.' to refer to both the source directory and
214# the corresponding build directory to pick up generated include
215# files.
216env.Append(CPPPATH=Dir('.'))
217
218# Add a flag defining what THE_ISA should be for all compilation
219env.Append(CPPDEFINES=[('THE_ISA','%s_ISA' % env['TARGET_ISA'].upper())])
220
221arch_sources = SConscript(os.path.join('arch', 'SConscript'), exports = 'env')
222
223cpu_sources = SConscript(os.path.join('cpu', 'SConscript'), exports = 'env')
224
225if env['FULL_SYSTEM']:
226    dev_sources = SConscript(os.path.join('dev', 'SConscript'),
227                             exports = 'env')
228    full_system_sources += dev_sources
229
230    kern_sources = SConscript(os.path.join('kern', 'SConscript'),
231                              exports = 'env')
232    full_system_sources += kern_sources
233
234# Set up complete list of sources based on configuration.
235sources = base_sources + arch_sources + cpu_sources
236
237# encumbered should be last because we're adding to some of the other groups
238if isfile(joinpath(env['SRCDIR'], 'encumbered/SConscript')):
239    sources += SConscript('encumbered/SConscript', exports = 'env')
240
241
242if env['FULL_SYSTEM']:
243    sources += full_system_sources
244else:
245    sources += syscall_emulation_sources
246
247if env['USE_MYSQL']:
248    sources += mysql_sources
249
250for opt in env.ExportOptions:
251    env.ConfigFile(opt)
252
253###################################################
254#
255# Special build rules.
256#
257###################################################
258
259# base/traceflags.{cc,hh} are generated from base/traceflags.py.
260# $TARGET.base will expand to "<build-dir>/base/traceflags".
261env.Command(Split('base/traceflags.hh base/traceflags.cc'),
262            'base/traceflags.py',
263            'python $SOURCE $TARGET.base')
264
265SConscript('python/SConscript', exports = ['env'])
266
267# This function adds the specified sources to the given build
268# environment, and returns a list of all the corresponding SCons
269# Object nodes (including an extra one for date.cc).  We explicitly
270# add the Object nodes so we can set up special dependencies for
271# date.cc.
272def make_objs(sources, env):
273    objs = [env.Object(s) for s in sources]
274    # make date.cc depend on all other objects so it always gets
275    # recompiled whenever anything else does
276    date_obj = env.Object('base/date.cc')
277    env.Depends(date_obj, objs)
278    objs.append(date_obj)
279    return objs
280
281###################################################
282#
283# Define binaries.  Each different build type (debug, opt, etc.) gets
284# a slightly different build environment.
285#
286###################################################
287
288# List of constructed environments to pass back to SConstruct
289envList = []
290
291# Function to create a new build environment as clone of current
292# environment 'env' with modified object suffix and optional stripped
293# binary.  Additional keyword arguments are appended to corresponding
294# build environment vars.
295def makeEnv(label, objsfx, strip = False, **kwargs):
296    newEnv = env.Copy(OBJSUFFIX=objsfx)
297    newEnv.Label = label
298    newEnv.Append(**kwargs)
299    exe = 'm5.' + label  # final executable
300    bin = exe + '.bin'   # executable w/o appended Python zip archive
301    newEnv.Program(bin, make_objs(sources, newEnv))
302    if strip:
303        stripped_bin = bin + '.stripped'
304        newEnv.Command(stripped_bin, bin, 'strip $SOURCE -o $TARGET')
305        bin = stripped_bin
306    targets = newEnv.Concat(exe, [bin, 'python/m5py.zip'])
307    newEnv.M5Binary = targets[0]
308    envList.append(newEnv)
309
310# Debug binary
311# Solaris seems to have some issue with DWARF2 debugging information, it's ok
312# with stabs though
313if sys.platform == 'sunos5':
314   debug_flag = '-gstabs+'
315else:
316   debug_flag = '-ggdb3'
317
318makeEnv('debug', '.do',
319        CCFLAGS = Split('%s -O0' % debug_flag),
320        CPPDEFINES = ['DEBUG', 'TRACING_ON=1'])
321
322# Optimized binary
323makeEnv('opt', '.o',
324        CCFLAGS = Split('-g -O3'),
325        CPPDEFINES = ['TRACING_ON=1'])
326
327# "Fast" binary
328makeEnv('fast', '.fo', strip = True,
329        CCFLAGS = Split('-O3'),
330        CPPDEFINES = ['NDEBUG', 'TRACING_ON=0'])
331
332# Profiled binary
333makeEnv('prof', '.po',
334        CCFLAGS = Split('-O3 -g -pg'),
335        LINKFLAGS = '-pg')
336
337Return('envList')
338