SConscript revision 2629 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29import os
30import sys
31from os.path import isdir
32
33# This file defines how to build a particular configuration of M5
34# based on variable settings in the 'env' build environment.
35
36# Import build environment variable from SConstruct.
37Import('env')
38
39###################################################
40#
41# Define needed sources.
42#
43###################################################
44
45# Base sources used by all configurations.
46
47base_sources = Split('''
48	base/circlebuf.cc
49	base/copyright.cc
50	base/cprintf.cc
51        base/embedfile.cc
52	base/fast_alloc.cc
53	base/fifo_buffer.cc
54	base/hostinfo.cc
55	base/hybrid_pred.cc
56	base/inifile.cc
57	base/intmath.cc
58	base/match.cc
59	base/misc.cc
60	base/output.cc
61	base/pollevent.cc
62	base/range.cc
63	base/random.cc
64	base/sat_counter.cc
65        base/serializer.cc
66	base/socket.cc
67	base/statistics.cc
68	base/str.cc
69	base/time.cc
70	base/trace.cc
71	base/traceflags.cc
72	base/userinfo.cc
73	base/compression/lzss_compression.cc
74	base/loader/aout_object.cc
75	base/loader/ecoff_object.cc
76	base/loader/elf_object.cc
77	base/loader/object_file.cc
78	base/loader/symtab.cc
79	base/stats/events.cc
80	base/stats/statdb.cc
81	base/stats/visit.cc
82	base/stats/text.cc
83
84	cpu/base.cc
85	cpu/cpu_exec_context.cc
86	cpu/exetrace.cc
87        cpu/op_class.cc
88	cpu/pc_event.cc
89	cpu/static_inst.cc
90        cpu/sampler/sampler.cc
91    
92        mem/bridge.cc
93        mem/bus.cc
94        mem/connector.cc
95        mem/mem_object.cc
96        mem/packet.cc
97        mem/physical.cc
98        mem/port.cc
99        mem/request.cc
100
101        python/pyconfig.cc
102        python/embedded_py.cc
103
104	sim/builder.cc
105	sim/configfile.cc
106	sim/debug.cc
107	sim/eventq.cc
108	sim/faults.cc
109	sim/main.cc
110	sim/param.cc
111	sim/profile.cc
112	sim/root.cc
113	sim/serialize.cc
114	sim/sim_events.cc
115	sim/sim_exit.cc
116	sim/sim_object.cc
117	sim/startup.cc
118	sim/stat_context.cc
119	sim/stat_control.cc
120	sim/system.cc
121	sim/trace_context.cc
122        ''')
123
124# Old FullCPU sources
125full_cpu_sources = Split('''
126	encumbered/cpu/full/bpred.cc
127	encumbered/cpu/full/commit.cc
128	encumbered/cpu/full/cpu.cc
129	encumbered/cpu/full/create_vector.cc
130	encumbered/cpu/full/cv_spec_state.cc
131	encumbered/cpu/full/dd_queue.cc
132	encumbered/cpu/full/dep_link.cc
133	encumbered/cpu/full/dispatch.cc
134	encumbered/cpu/full/dyn_inst.cc
135	encumbered/cpu/full/execute.cc
136	encumbered/cpu/full/fetch.cc
137	encumbered/cpu/full/floss_reasons.cc
138	encumbered/cpu/full/fu_pool.cc
139	encumbered/cpu/full/inst_fifo.cc
140	encumbered/cpu/full/instpipe.cc
141	encumbered/cpu/full/issue.cc
142	encumbered/cpu/full/ls_queue.cc
143	encumbered/cpu/full/machine_queue.cc
144        encumbered/cpu/full/pipetrace.cc
145        encumbered/cpu/full/readyq.cc
146        encumbered/cpu/full/reg_info.cc
147        encumbered/cpu/full/rob_station.cc
148        encumbered/cpu/full/spec_memory.cc
149        encumbered/cpu/full/spec_state.cc
150        encumbered/cpu/full/storebuffer.cc
151        encumbered/cpu/full/writeback.cc
152        encumbered/cpu/full/iq/iq_station.cc
153        encumbered/cpu/full/iq/iqueue.cc
154        encumbered/cpu/full/iq/segmented/chain_info.cc
155        encumbered/cpu/full/iq/segmented/chain_wire.cc
156        encumbered/cpu/full/iq/segmented/iq_seg.cc
157        encumbered/cpu/full/iq/segmented/iq_segmented.cc
158        encumbered/cpu/full/iq/segmented/seg_chain.cc
159        encumbered/cpu/full/iq/seznec/iq_seznec.cc
160        encumbered/cpu/full/iq/standard/iq_standard.cc
161        ''')
162
163trace_reader_sources = Split('''
164        cpu/trace/reader/mem_trace_reader.cc
165        cpu/trace/reader/ibm_reader.cc
166        cpu/trace/reader/itx_reader.cc
167        cpu/trace/reader/m5_reader.cc
168        cpu/trace/opt_cpu.cc
169        cpu/trace/trace_cpu.cc
170        ''')
171
172
173
174# MySql sources
175mysql_sources = Split('''
176	base/mysql.cc
177	base/stats/mysql.cc
178        ''')
179
180# Full-system sources
181full_system_sources = Split('''
182	base/crc.cc
183	base/inet.cc
184	base/remote_gdb.cc
185
186	cpu/intr_control.cc
187        cpu/profile.cc
188
189	dev/alpha_console.cc
190	dev/baddev.cc
191	dev/disk_image.cc
192	dev/etherbus.cc
193	dev/etherdump.cc
194	dev/etherint.cc
195	dev/etherlink.cc
196	dev/etherpkt.cc
197	dev/ethertap.cc	
198        dev/ide_ctrl.cc
199	dev/ide_disk.cc
200	dev/io_device.cc
201	dev/isa_fake.cc
202	dev/ns_gige.cc
203	dev/pciconfigall.cc
204	dev/pcidev.cc
205	dev/pcifake.cc
206	dev/pktfifo.cc
207	dev/platform.cc
208        dev/simconsole.cc
209	dev/simple_disk.cc
210	dev/sinic.cc
211	dev/tsunami.cc
212	dev/tsunami_cchip.cc
213	dev/tsunami_io.cc
214	dev/tsunami_fake.cc
215	dev/tsunami_pchip.cc
216
217	dev/uart.cc
218	dev/uart8250.cc
219
220	kern/kernel_binning.cc
221	kern/kernel_stats.cc
222	kern/system_events.cc
223	kern/linux/events.cc
224	kern/linux/linux_syscalls.cc
225	kern/linux/printk.cc
226
227        mem/vport.cc
228
229	sim/pseudo_inst.cc
230        ''')
231
232
233if env['TARGET_ISA'] == 'alpha':
234    full_system_sources += Split('''
235	kern/tru64/dump_mbuf.cc
236	kern/tru64/printf.cc
237	kern/tru64/tru64_events.cc
238	kern/tru64/tru64_syscalls.cc
239        ''')
240
241# turbolaser encumbered sources
242turbolaser_sources = Split('''
243	encumbered/dev/dma.cc
244	encumbered/dev/etherdev.cc
245	encumbered/dev/scsi.cc
246	encumbered/dev/scsi_ctrl.cc
247	encumbered/dev/scsi_disk.cc
248	encumbered/dev/scsi_none.cc
249	encumbered/dev/tlaser_clock.cc
250	encumbered/dev/tlaser_ipi.cc
251	encumbered/dev/tlaser_mbox.cc
252	encumbered/dev/tlaser_mc146818.cc
253	encumbered/dev/tlaser_node.cc
254	encumbered/dev/tlaser_pcia.cc
255	encumbered/dev/tlaser_pcidev.cc
256	encumbered/dev/tlaser_serial.cc
257	encumbered/dev/turbolaser.cc
258	encumbered/dev/uart8530.cc
259        ''')
260
261# Syscall emulation (non-full-system) sources
262syscall_emulation_sources = Split('''
263        mem/translating_port.cc
264        mem/page_table.cc
265	sim/process.cc
266	sim/syscall_emul.cc
267        ''')
268
269#if env['TARGET_ISA'] == 'alpha':
270#    syscall_emulation_sources += Split('''
271#        kern/tru64/tru64.cc
272#        ''')
273
274alpha_eio_sources = Split('''
275	encumbered/eio/exolex.cc
276	encumbered/eio/libexo.cc
277	encumbered/eio/eio.cc
278        ''')
279
280if env['TARGET_ISA'] == 'ALPHA_ISA':
281    syscall_emulation_sources += alpha_eio_sources
282    
283memtest_sources = Split('''
284	cpu/memtest/memtest.cc
285        ''')
286
287# Add a flag defining what THE_ISA should be for all compilation
288env.Append(CPPDEFINES=[('THE_ISA','%s_ISA' % env['TARGET_ISA'].upper())])
289
290arch_sources = SConscript('arch/SConscript',
291                          exports = 'env', duplicate = False)
292
293cpu_sources = SConscript('cpu/SConscript',
294                         exports = 'env', duplicate = False)
295
296# This is outside of cpu/SConscript since the source directory isn't
297# underneath 'cpu'.
298if 'FullCPU' in env['CPU_MODELS']:
299    cpu_sources += full_cpu_sources
300
301# Set up complete list of sources based on configuration.
302sources = base_sources + arch_sources + cpu_sources
303
304if env['FULL_SYSTEM']:
305    sources += full_system_sources
306    if env['ALPHA_TLASER']:
307        sources += turbolaser_sources
308else:
309    sources += syscall_emulation_sources
310
311if env['USE_MYSQL']:
312    sources += mysql_sources
313
314for opt in env.ExportOptions:
315    env.ConfigFile(opt)
316
317###################################################
318#
319# Special build rules.
320#
321###################################################
322
323# base/traceflags.{cc,hh} are generated from base/traceflags.py.
324# $TARGET.base will expand to "<build-dir>/base/traceflags".
325env.Command(Split('base/traceflags.hh base/traceflags.cc'),
326            'base/traceflags.py',
327            'python $SOURCE $TARGET.base')
328
329# libelf build is described in its own SConscript file.
330# SConscript-local is the per-config build, which just copies some
331# header files into a place where they can be found.
332SConscript('libelf/SConscript-local', exports = 'env', duplicate=0)
333SConscript('python/SConscript', exports = ['env'], duplicate=0)
334
335# This function adds the specified sources to the given build
336# environment, and returns a list of all the corresponding SCons
337# Object nodes (including an extra one for date.cc).  We explicitly
338# add the Object nodes so we can set up special dependencies for
339# date.cc.
340def make_objs(sources, env):
341    objs = [env.Object(s) for s in sources]
342    # make date.cc depend on all other objects so it always gets
343    # recompiled whenever anything else does
344    date_obj = env.Object('base/date.cc')
345    env.Depends(date_obj, objs)
346    objs.append(date_obj)
347    return objs
348
349###################################################
350#
351# Define binaries.  Each different build type (debug, opt, etc.) gets
352# a slightly different build environment.
353#
354###################################################
355
356# Include file paths are rooted in this directory.  SCons will
357# automatically expand '.' to refer to both the source directory and
358# the corresponding build directory to pick up generated include
359# files.
360env.Append(CPPPATH='.')
361env.Append(CPPPATH='./libelf')
362
363# Debug binary
364debugEnv = env.Copy(OBJSUFFIX='.do')
365debugEnv.Label = 'debug'
366debugEnv.Append(CCFLAGS=Split('-g3 -gdwarf-2 -O0'))
367debugEnv.Append(CPPDEFINES='DEBUG')
368tlist = debugEnv.Program(target = 'm5.debug',
369                         source = make_objs(sources, debugEnv))
370debugEnv.M5Binary = tlist[0]
371
372# Optimized binary
373optEnv = env.Copy()
374optEnv.Label = 'opt'
375optEnv.Append(CCFLAGS=Split('-g -O3'))
376tlist = optEnv.Program(target = 'm5.opt',
377                       source = make_objs(sources, optEnv))
378optEnv.M5Binary = tlist[0]
379
380# "Fast" binary
381fastEnv = env.Copy(OBJSUFFIX='.fo')
382fastEnv.Label = 'fast'
383fastEnv.Append(CCFLAGS=Split('-O3'))
384fastEnv.Append(CPPDEFINES='NDEBUG')
385fastEnv.Program(target = 'm5.fast.unstripped',
386                source = make_objs(sources, fastEnv))
387tlist = fastEnv.Command(target = 'm5.fast',
388                        source = 'm5.fast.unstripped',
389                        action = 'strip $SOURCE -o $TARGET')
390fastEnv.M5Binary = tlist[0]
391
392# Profiled binary
393profEnv = env.Copy(OBJSUFFIX='.po')
394profEnv.Label = 'prof'
395profEnv.Append(CCFLAGS=Split('-O3 -g -pg'), LINKFLAGS='-pg')
396tlist = profEnv.Program(target = 'm5.prof',
397                        source = make_objs(sources, profEnv))
398profEnv.M5Binary = tlist[0]
399
400envList = [debugEnv, optEnv, fastEnv, profEnv]
401
402Return('envList')
403