SConscript revision 2190 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29import os
30import sys
31from os.path import isdir
32
33# This file defines how to build a particular configuration of M5
34# based on variable settings in the 'env' build environment.
35
36# Import build environment variable from SConstruct.
37Import('env')
38
39###################################################
40#
41# Define needed sources.
42#
43###################################################
44
45# Base sources used by all configurations.
46
47base_sources = Split('''
48	base/circlebuf.cc
49	base/copyright.cc
50	base/cprintf.cc
51        base/embedfile.cc
52	base/fast_alloc.cc
53	base/fifo_buffer.cc
54	base/hostinfo.cc
55	base/hybrid_pred.cc
56	base/inifile.cc
57	base/intmath.cc
58	base/match.cc
59	base/misc.cc
60	base/output.cc
61	base/pollevent.cc
62	base/range.cc
63	base/random.cc
64	base/sat_counter.cc
65	base/socket.cc
66	base/statistics.cc
67	base/str.cc
68	base/time.cc
69	base/trace.cc
70	base/traceflags.cc
71	base/userinfo.cc
72	base/compression/lzss_compression.cc
73	base/loader/aout_object.cc
74	base/loader/ecoff_object.cc
75	base/loader/elf_object.cc
76	base/loader/object_file.cc
77	base/loader/symtab.cc
78	base/stats/events.cc
79	base/stats/statdb.cc
80	base/stats/visit.cc
81	base/stats/text.cc
82
83	cpu/base.cc
84        cpu/base_dyn_inst.cc
85	cpu/cpu_exec_context.cc
86	cpu/exetrace.cc
87	cpu/pc_event.cc
88	cpu/static_inst.cc
89        cpu/sampler/sampler.cc
90        cpu/trace/reader/mem_trace_reader.cc
91        cpu/trace/reader/ibm_reader.cc
92        cpu/trace/reader/itx_reader.cc
93        cpu/trace/reader/m5_reader.cc
94        cpu/trace/opt_cpu.cc
95        cpu/trace/trace_cpu.cc
96
97	encumbered/mem/functional/main.cc
98
99	mem/base_hier.cc
100	mem/base_mem.cc
101	mem/hier_params.cc
102	mem/mem_cmd.cc
103	mem/mem_debug.cc
104	mem/mem_req.cc
105	mem/memory_interface.cc
106	mem/bus/base_interface.cc
107	mem/bus/bus.cc
108	mem/bus/bus_bridge.cc
109	mem/bus/bus_bridge_master.cc
110	mem/bus/bus_bridge_slave.cc
111	mem/bus/bus_interface.cc
112	mem/bus/dma_bus_interface.cc
113	mem/bus/dma_interface.cc
114	mem/bus/master_interface.cc
115	mem/bus/slave_interface.cc
116	mem/cache/base_cache.cc
117	mem/cache/cache.cc
118	mem/cache/cache_builder.cc
119	mem/cache/coherence/coherence_protocol.cc
120	mem/cache/coherence/uni_coherence.cc
121	mem/cache/miss/blocking_buffer.cc
122	mem/cache/miss/miss_queue.cc
123	mem/cache/miss/mshr.cc
124	mem/cache/miss/mshr_queue.cc
125        mem/cache/prefetch/base_prefetcher.cc
126        mem/cache/prefetch/prefetcher.cc
127        mem/cache/prefetch/tagged_prefetcher.cc
128	mem/cache/tags/base_tags.cc
129	mem/cache/tags/cache_tags.cc	
130	mem/cache/tags/fa_lru.cc
131	mem/cache/tags/iic.cc
132	mem/cache/tags/lru.cc
133	mem/cache/tags/repl/gen.cc
134	mem/cache/tags/repl/repl.cc
135	mem/cache/tags/split.cc
136	mem/cache/tags/split_lru.cc
137	mem/cache/tags/split_lifo.cc
138	mem/functional/functional.cc
139	mem/timing/base_memory.cc
140	mem/timing/memory_builder.cc
141	mem/timing/simple_mem_bank.cc
142        mem/trace/itx_writer.cc
143	mem/trace/mem_trace_writer.cc
144	mem/trace/m5_writer.cc
145
146        python/pyconfig.cc
147        python/embedded_py.cc
148
149	sim/builder.cc
150	sim/configfile.cc
151	sim/debug.cc
152	sim/eventq.cc
153	sim/faults.cc
154	sim/main.cc
155	sim/param.cc
156	sim/profile.cc
157	sim/root.cc
158	sim/serialize.cc
159	sim/sim_events.cc
160	sim/sim_exit.cc
161	sim/sim_object.cc
162	sim/startup.cc
163	sim/stat_context.cc
164	sim/stat_control.cc
165	sim/trace_context.cc
166        ''')
167
168# Old FullCPU sources
169full_cpu_sources = Split('''
170	encumbered/cpu/full/bpred.cc
171	encumbered/cpu/full/commit.cc
172	encumbered/cpu/full/cpu.cc
173	encumbered/cpu/full/create_vector.cc
174	encumbered/cpu/full/cv_spec_state.cc
175	encumbered/cpu/full/dd_queue.cc
176	encumbered/cpu/full/dep_link.cc
177	encumbered/cpu/full/dispatch.cc
178	encumbered/cpu/full/dyn_inst.cc
179	encumbered/cpu/full/execute.cc
180	encumbered/cpu/full/fetch.cc
181	encumbered/cpu/full/floss_reasons.cc
182	encumbered/cpu/full/fu_pool.cc
183	encumbered/cpu/full/inst_fifo.cc
184	encumbered/cpu/full/instpipe.cc
185	encumbered/cpu/full/issue.cc
186	encumbered/cpu/full/ls_queue.cc
187	encumbered/cpu/full/machine_queue.cc
188        encumbered/cpu/full/pipetrace.cc
189        encumbered/cpu/full/readyq.cc
190        encumbered/cpu/full/reg_info.cc
191        encumbered/cpu/full/rob_station.cc
192        encumbered/cpu/full/spec_memory.cc
193        encumbered/cpu/full/spec_state.cc
194        encumbered/cpu/full/storebuffer.cc
195        encumbered/cpu/full/writeback.cc
196        encumbered/cpu/full/iq/iq_station.cc
197        encumbered/cpu/full/iq/iqueue.cc
198        encumbered/cpu/full/iq/segmented/chain_info.cc
199        encumbered/cpu/full/iq/segmented/chain_wire.cc
200        encumbered/cpu/full/iq/segmented/iq_seg.cc
201        encumbered/cpu/full/iq/segmented/iq_segmented.cc
202        encumbered/cpu/full/iq/segmented/seg_chain.cc
203        encumbered/cpu/full/iq/seznec/iq_seznec.cc
204        encumbered/cpu/full/iq/standard/iq_standard.cc
205        ''')
206
207# MySql sources
208mysql_sources = Split('''
209	base/mysql.cc
210	base/stats/mysql.cc
211        ''')
212
213# Full-system sources
214full_system_sources = Split('''
215	base/crc.cc
216	base/inet.cc
217	base/remote_gdb.cc
218
219	cpu/intr_control.cc
220        cpu/profile.cc
221
222	dev/alpha_console.cc
223	dev/baddev.cc
224        dev/simconsole.cc
225	dev/disk_image.cc
226	dev/etherbus.cc
227	dev/etherdump.cc
228	dev/etherint.cc
229	dev/etherlink.cc
230	dev/etherpkt.cc
231	dev/ethertap.cc
232	dev/ide_ctrl.cc
233	dev/ide_disk.cc
234	dev/io_device.cc
235	dev/ns_gige.cc
236	dev/pciconfigall.cc
237	dev/pcidev.cc
238	dev/pcifake.cc
239	dev/pktfifo.cc
240	dev/platform.cc
241	dev/sinic.cc
242	dev/simple_disk.cc
243	dev/tsunami.cc
244	dev/tsunami_cchip.cc
245	dev/isa_fake.cc
246	dev/tsunami_io.cc
247	dev/tsunami_pchip.cc
248	dev/uart.cc
249	dev/uart8250.cc
250
251	kern/kernel_binning.cc
252	kern/kernel_stats.cc
253	kern/system_events.cc
254	kern/freebsd/freebsd_system.cc
255	kern/linux/linux_syscalls.cc
256	kern/linux/linux_system.cc
257	kern/linux/printk.cc
258	kern/tru64/dump_mbuf.cc
259	kern/tru64/printf.cc
260	kern/tru64/tru64_events.cc
261	kern/tru64/tru64_syscalls.cc
262	kern/tru64/tru64_system.cc
263
264	mem/functional/memory_control.cc
265	mem/functional/physical.cc
266
267	sim/system.cc
268	sim/pseudo_inst.cc
269        ''')
270
271# turbolaser encumbered sources
272turbolaser_sources = Split('''
273	encumbered/dev/dma.cc
274	encumbered/dev/etherdev.cc
275	encumbered/dev/scsi.cc
276	encumbered/dev/scsi_ctrl.cc
277	encumbered/dev/scsi_disk.cc
278	encumbered/dev/scsi_none.cc
279	encumbered/dev/tlaser_clock.cc
280	encumbered/dev/tlaser_ipi.cc
281	encumbered/dev/tlaser_mbox.cc
282	encumbered/dev/tlaser_mc146818.cc
283	encumbered/dev/tlaser_node.cc
284	encumbered/dev/tlaser_pcia.cc
285	encumbered/dev/tlaser_pcidev.cc
286	encumbered/dev/tlaser_serial.cc
287	encumbered/dev/turbolaser.cc
288	encumbered/dev/uart8530.cc
289        ''')
290
291# Syscall emulation (non-full-system) sources
292syscall_emulation_sources = Split('''
293	cpu/memtest/memtest.cc
294	encumbered/eio/eio.cc
295	encumbered/eio/exolex.cc
296	encumbered/eio/libexo.cc
297        kern/linux/linux.cc
298        kern/tru64/tru64.cc
299	sim/process.cc
300	sim/syscall_emul.cc
301        ''')
302
303# The following stuff (targetarch code and global define of THE_ISA)
304# are legacy things that assume we're only compiling one ISA at a
305# time.  These will have to go away if we want to build a binary that
306# supports multiple ISAs.
307
308targetarch_files = Split('''
309        alpha_linux_process.hh
310        alpha_memory.hh
311        alpha_tru64_process.hh
312        aout_machdep.h
313        arguments.hh
314        ecoff_machdep.h
315        ev5.hh
316        faults.hh
317        stacktrace.hh
318        vtophys.hh
319        ''')
320
321# Set up bridging headers to the architecture specific versions
322for f in targetarch_files:
323    env.Command('targetarch/' + f, 'arch/%s/%s' % (env['TARGET_ISA'], f),
324                '''echo '#include "arch/%s/%s"' > $TARGET''' % (env['TARGET_ISA'], f))
325
326# Add a flag defining what THE_ISA should be for all compilation
327env.Append(CPPDEFINES=[('THE_ISA','%s_ISA' % env['TARGET_ISA'].upper())])
328
329arch_sources = SConscript('arch/SConscript',
330                          exports = 'env', duplicate = False)
331
332cpu_sources = SConscript('cpu/SConscript',
333                         exports = 'env', duplicate = False)
334
335# This is outside of cpu/SConscript since the source directory isn't
336# underneath 'cpu'.
337if 'FullCPU' in env['CPU_MODELS']:
338    cpu_sources += full_cpu_sources
339
340# Set up complete list of sources based on configuration.
341sources = base_sources + arch_sources + cpu_sources
342
343if env['FULL_SYSTEM']:
344    sources += full_system_sources
345    if env['ALPHA_TLASER']:
346        sources += turbolaser_sources
347else:
348    sources += syscall_emulation_sources
349
350if env['USE_MYSQL']:
351    sources += mysql_sources
352
353for opt in env.ExportOptions:
354    env.ConfigFile(opt)
355
356###################################################
357#
358# Special build rules.
359#
360###################################################
361
362# base/traceflags.{cc,hh} are generated from base/traceflags.py.
363# $TARGET.base will expand to "<build-dir>/base/traceflags".
364env.Command(Split('base/traceflags.hh base/traceflags.cc'),
365            'base/traceflags.py',
366            'python $SOURCE $TARGET.base')
367
368# libelf build is described in its own SConscript file.
369# SConscript-local is the per-config build, which just copies some
370# header files into a place where they can be found.
371SConscript('libelf/SConscript-local', exports = 'env', duplicate=0)
372SConscript('python/SConscript', exports = ['env'], duplicate=0)
373
374# This function adds the specified sources to the given build
375# environment, and returns a list of all the corresponding SCons
376# Object nodes (including an extra one for date.cc).  We explicitly
377# add the Object nodes so we can set up special dependencies for
378# date.cc.
379def make_objs(sources, env):
380    objs = [env.Object(s) for s in sources]
381    # make date.cc depend on all other objects so it always gets
382    # recompiled whenever anything else does
383    date_obj = env.Object('base/date.cc')
384    env.Depends(date_obj, objs)
385    objs.append(date_obj)
386    return objs
387
388###################################################
389#
390# Define binaries.  Each different build type (debug, opt, etc.) gets
391# a slightly different build environment.
392#
393###################################################
394
395# Include file paths are rooted in this directory.  SCons will
396# automatically expand '.' to refer to both the source directory and
397# the corresponding build directory to pick up generated include
398# files.
399env.Append(CPPPATH='.')
400
401# Debug binary
402debugEnv = env.Copy(OBJSUFFIX='.do')
403debugEnv.Label = 'debug'
404debugEnv.Append(CCFLAGS=Split('-g -gstabs+ -O0'))
405debugEnv.Append(CPPDEFINES='DEBUG')
406tlist = debugEnv.Program(target = 'm5.debug',
407                         source = make_objs(sources, debugEnv))
408debugEnv.M5Binary = tlist[0]
409
410# Optimized binary
411optEnv = env.Copy()
412optEnv.Label = 'opt'
413optEnv.Append(CCFLAGS=Split('-g -O5'))
414tlist = optEnv.Program(target = 'm5.opt',
415                       source = make_objs(sources, optEnv))
416optEnv.M5Binary = tlist[0]
417
418# "Fast" binary
419fastEnv = env.Copy(OBJSUFFIX='.fo')
420fastEnv.Label = 'fast'
421fastEnv.Append(CCFLAGS=Split('-O5'))
422fastEnv.Append(CPPDEFINES='NDEBUG')
423fastEnv.Program(target = 'm5.fast.unstripped',
424                source = make_objs(sources, fastEnv))
425tlist = fastEnv.Command(target = 'm5.fast',
426                        source = 'm5.fast.unstripped',
427                        action = 'strip $SOURCE -o $TARGET')
428fastEnv.M5Binary = tlist[0]
429
430# Profiled binary
431profEnv = env.Copy(OBJSUFFIX='.po')
432profEnv.Label = 'prof'
433profEnv.Append(CCFLAGS=Split('-O5 -g -pg'), LINKFLAGS='-pg')
434tlist = profEnv.Program(target = 'm5.prof',
435                        source = make_objs(sources, profEnv))
436profEnv.M5Binary = tlist[0]
437
438envList = [debugEnv, optEnv, fastEnv, profEnv]
439
440Return('envList')
441