SConstruct revision 2668:1f891cd3d920 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29###################################################
30#
31# SCons top-level build description (SConstruct) file.
32#
33# While in this directory ('m5'), just type 'scons' to build the default
34# configuration (see below), or type 'scons build/<CONFIG>/<binary>'
35# to build some other configuration (e.g., 'build/ALPHA_FS/m5.opt' for
36# the optimized full-system version).
37#
38# You can build M5 in a different directory as long as there is a
39# 'build/<CONFIG>' somewhere along the target path.  The build system
40# expdects that all configs under the same build directory are being
41# built for the same host system.
42#
43# Examples:
44#   These two commands are equivalent.  The '-u' option tells scons to
45#   search up the directory tree for this SConstruct file.
46#   % cd <path-to-src>/m5 ; scons build/ALPHA_FS/m5.debug
47#   % cd <path-to-src>/m5/build/ALPHA_FS; scons -u m5.debug
48#   These two commands are equivalent and demonstrate building in a
49#   directory outside of the source tree.  The '-C' option tells scons
50#   to chdir to the specified directory to find this SConstruct file.
51#   % cd <path-to-src>/m5 ; scons /local/foo/build/ALPHA_FS/m5.debug
52#   % cd /local/foo/build/ALPHA_FS; scons -C <path-to-src>/m5 m5.debug
53#
54# You can use 'scons -H' to print scons options.  If you're in this
55# 'm5' directory (or use -u or -C to tell scons where to find this
56# file), you can use 'scons -h' to print all the M5-specific build
57# options as well.
58#
59###################################################
60
61# Python library imports
62import sys
63import os
64
65# Check for recent-enough Python and SCons versions.  If your system's
66# default installation of Python is not recent enough, you can use a
67# non-default installation of the Python interpreter by either (1)
68# rearranging your PATH so that scons finds the non-default 'python'
69# first or (2) explicitly invoking an alternative interpreter on the
70# scons script, e.g., "/usr/local/bin/python2.4 `which scons` [args]".
71EnsurePythonVersion(2,4)
72
73# Ironically, SCons 0.96 dies if you give EnsureSconsVersion a
74# 3-element version number.
75min_scons_version = (0,96,91)
76try:
77    EnsureSConsVersion(*min_scons_version)
78except:
79    print "Error checking current SCons version."
80    print "SCons", ".".join(map(str,min_scons_version)), "or greater required."
81    Exit(2)
82    
83
84# The absolute path to the current directory (where this file lives).
85ROOT = Dir('.').abspath
86
87# Paths to the M5 and external source trees.
88SRCDIR = os.path.join(ROOT, 'src')
89
90# tell python where to find m5 python code
91sys.path.append(os.path.join(ROOT, 'src/python'))
92
93###################################################
94#
95# Figure out which configurations to set up based on the path(s) of
96# the target(s).
97#
98###################################################
99
100# Find default configuration & binary.
101Default(os.environ.get('M5_DEFAULT_BINARY', 'build/ALPHA_SE/m5.debug'))
102
103# Ask SCons which directory it was invoked from.
104launch_dir = GetLaunchDir()
105
106# Make targets relative to invocation directory
107abs_targets = map(lambda x: os.path.normpath(os.path.join(launch_dir, str(x))),
108                  BUILD_TARGETS)
109
110# helper function: find last occurrence of element in list
111def rfind(l, elt, offs = -1):
112    for i in range(len(l)+offs, 0, -1):
113        if l[i] == elt:
114            return i
115    raise ValueError, "element not found"
116
117# Each target must have 'build' in the interior of the path; the
118# directory below this will determine the build parameters.  For
119# example, for target 'foo/bar/build/ALPHA_SE/arch/alpha/blah.do' we
120# recognize that ALPHA_SE specifies the configuration because it
121# follow 'build' in the bulid path.
122
123# Generate a list of the unique build roots and configs that the
124# collected targets reference.
125build_paths = []
126build_root = None
127for t in abs_targets:
128    path_dirs = t.split('/')
129    try:
130        build_top = rfind(path_dirs, 'build', -2)
131    except:
132        print "Error: no non-leaf 'build' dir found on target path", t
133        Exit(1)
134    this_build_root = os.path.join('/',*path_dirs[:build_top+1])
135    if not build_root:
136        build_root = this_build_root
137    else:
138        if this_build_root != build_root:
139            print "Error: build targets not under same build root\n"\
140                  "  %s\n  %s" % (build_root, this_build_root)
141            Exit(1)
142    build_path = os.path.join('/',*path_dirs[:build_top+2])
143    if build_path not in build_paths:
144        build_paths.append(build_path)
145
146###################################################
147#
148# Set up the default build environment.  This environment is copied
149# and modified according to each selected configuration.
150#
151###################################################
152
153env = Environment(ENV = os.environ,  # inherit user's environment vars
154                  ROOT = ROOT,
155                  SRCDIR = SRCDIR)
156
157env.SConsignFile("sconsign")
158
159# I waffle on this setting... it does avoid a few painful but
160# unnecessary builds, but it also seems to make trivial builds take
161# noticeably longer.
162if False:
163    env.TargetSignatures('content')
164
165# M5_PLY is used by isa_parser.py to find the PLY package.
166env.Append(ENV = { 'M5_PLY' : Dir('ext/ply') })
167
168# Set up default C++ compiler flags
169env.Append(CCFLAGS='-pipe')
170env.Append(CCFLAGS='-fno-strict-aliasing')
171env.Append(CCFLAGS=Split('-Wall -Wno-sign-compare -Werror -Wundef'))
172if sys.platform == 'cygwin':
173    # cygwin has some header file issues...
174    env.Append(CCFLAGS=Split("-Wno-uninitialized"))
175env.Append(CPPPATH=[Dir('ext/dnet')])
176
177# Find Python include and library directories for embedding the
178# interpreter.  For consistency, we will use the same Python
179# installation used to run scons (and thus this script).  If you want
180# to link in an alternate version, see above for instructions on how
181# to invoke scons with a different copy of the Python interpreter.
182
183# Get brief Python version name (e.g., "python2.4") for locating
184# include & library files
185py_version_name = 'python' + sys.version[:3]
186
187# include path, e.g. /usr/local/include/python2.4
188env.Append(CPPPATH = os.path.join(sys.exec_prefix, 'include', py_version_name))
189env.Append(LIBS = py_version_name)
190# add library path too if it's not in the default place
191if sys.exec_prefix != '/usr':
192    env.Append(LIBPATH = os.path.join(sys.exec_prefix, 'lib'))
193
194# Other default libraries
195env.Append(LIBS=['z'])
196
197# Platform-specific configuration.  Note again that we assume that all
198# builds under a given build root run on the same host platform.
199conf = Configure(env,
200                 conf_dir = os.path.join(build_root, '.scons_config'),
201                 log_file = os.path.join(build_root, 'scons_config.log'))
202
203# Check for <fenv.h> (C99 FP environment control)
204have_fenv = conf.CheckHeader('fenv.h', '<>')
205if not have_fenv:
206    print "Warning: Header file <fenv.h> not found."
207    print "         This host has no IEEE FP rounding mode control."
208
209# Check for mysql.
210mysql_config = WhereIs('mysql_config')
211have_mysql = mysql_config != None
212
213# Check MySQL version.
214if have_mysql:
215    mysql_version = os.popen(mysql_config + ' --version').read()
216    mysql_version = mysql_version.split('.')
217    mysql_major = int(mysql_version[0])
218    mysql_minor = int(mysql_version[1])
219    # This version check is probably overly conservative, but it deals
220    # with the versions we have installed.
221    if mysql_major < 4 or (mysql_major == 4 and mysql_minor < 1):
222        print "Warning: MySQL v4.1 or newer required."
223        have_mysql = False
224
225# Set up mysql_config commands.
226if have_mysql:
227    mysql_config_include = mysql_config + ' --include'
228    if os.system(mysql_config_include + ' > /dev/null') != 0:
229        # older mysql_config versions don't support --include, use
230        # --cflags instead
231        mysql_config_include = mysql_config + ' --cflags | sed s/\\\'//g'
232    # This seems to work in all versions
233    mysql_config_libs = mysql_config + ' --libs'
234
235env = conf.Finish()
236
237# Define the universe of supported ISAs
238env['ALL_ISA_LIST'] = ['alpha', 'sparc', 'mips']
239
240# Define the universe of supported CPU models
241env['ALL_CPU_LIST'] = ['AtomicSimpleCPU', 'TimingSimpleCPU',
242                       'FullCPU', 'AlphaFullCPU',
243                       'OzoneSimpleCPU', 'OzoneCPU', 'CheckerCPU']
244
245# Sticky options get saved in the options file so they persist from
246# one invocation to the next (unless overridden, in which case the new
247# value becomes sticky).
248sticky_opts = Options(args=ARGUMENTS)
249sticky_opts.AddOptions(
250    EnumOption('TARGET_ISA', 'Target ISA', 'alpha', env['ALL_ISA_LIST']),
251    BoolOption('FULL_SYSTEM', 'Full-system support', False),
252    # There's a bug in scons 0.96.1 that causes ListOptions with list
253    # values (more than one value) not to be able to be restored from
254    # a saved option file.  If this causes trouble then upgrade to
255    # scons 0.96.90 or later.
256    ListOption('CPU_MODELS', 'CPU models', 'AtomicSimpleCPU,TimingSimpleCPU',
257               env['ALL_CPU_LIST']),
258    BoolOption('ALPHA_TLASER',
259               'Model Alpha TurboLaser platform (vs. Tsunami)', False),
260    BoolOption('NO_FAST_ALLOC', 'Disable fast object allocator', False),
261    BoolOption('EFENCE', 'Link with Electric Fence malloc debugger',
262               False),
263    BoolOption('SS_COMPATIBLE_FP',
264               'Make floating-point results compatible with SimpleScalar',
265               False),
266    BoolOption('USE_SSE2',
267               'Compile for SSE2 (-msse2) to get IEEE FP on x86 hosts',
268               False),
269    BoolOption('STATS_BINNING', 'Bin statistics by CPU mode', have_mysql),
270    BoolOption('USE_MYSQL', 'Use MySQL for stats output', have_mysql),
271    BoolOption('USE_FENV', 'Use <fenv.h> IEEE mode control', have_fenv),
272    ('CC', 'C compiler', os.environ.get('CC', env['CC'])),
273    ('CXX', 'C++ compiler', os.environ.get('CXX', env['CXX'])),
274    BoolOption('BATCH', 'Use batch pool for build and tests', False),
275    ('BATCH_CMD', 'Batch pool submission command name', 'qdo')
276    )
277
278# Non-sticky options only apply to the current build.
279nonsticky_opts = Options(args=ARGUMENTS)
280nonsticky_opts.AddOptions(
281    BoolOption('update_ref', 'Update test reference outputs', False)
282    )
283
284# These options get exported to #defines in config/*.hh (see m5/SConscript).
285env.ExportOptions = ['FULL_SYSTEM', 'ALPHA_TLASER', 'USE_FENV', \
286                     'USE_MYSQL', 'NO_FAST_ALLOC', 'SS_COMPATIBLE_FP', \
287                     'STATS_BINNING']
288
289# Define a handy 'no-op' action
290def no_action(target, source, env):
291    return 0
292
293env.NoAction = Action(no_action, None)
294
295###################################################
296#
297# Define a SCons builder for configuration flag headers.
298#
299###################################################
300
301# This function generates a config header file that #defines the
302# option symbol to the current option setting (0 or 1).  The source
303# operands are the name of the option and a Value node containing the
304# value of the option.
305def build_config_file(target, source, env):
306    (option, value) = [s.get_contents() for s in source]
307    f = file(str(target[0]), 'w')
308    print >> f, '#define', option, value
309    f.close()
310    return None
311
312# Generate the message to be printed when building the config file.
313def build_config_file_string(target, source, env):
314    (option, value) = [s.get_contents() for s in source]
315    return "Defining %s as %s in %s." % (option, value, target[0])
316
317# Combine the two functions into a scons Action object.
318config_action = Action(build_config_file, build_config_file_string)
319
320# The emitter munges the source & target node lists to reflect what
321# we're really doing.
322def config_emitter(target, source, env):
323    # extract option name from Builder arg
324    option = str(target[0])
325    # True target is config header file
326    target = os.path.join('config', option.lower() + '.hh')
327    # Force value to 0/1 even if it's a Python bool
328    val = int(eval(str(env[option])))
329    # Sources are option name & value (packaged in SCons Value nodes)
330    return ([target], [Value(option), Value(val)])
331
332config_builder = Builder(emitter = config_emitter, action = config_action)
333
334env.Append(BUILDERS = { 'ConfigFile' : config_builder })
335
336###################################################
337#
338# Define a SCons builder for copying files.  This is used by the
339# Python zipfile code in src/python/SConscript, but is placed up here
340# since it's potentially more generally applicable.
341#
342###################################################
343
344copy_builder = Builder(action = Copy("$TARGET", "$SOURCE"))
345
346env.Append(BUILDERS = { 'CopyFile' : copy_builder })
347
348###################################################
349#
350# Define a simple SCons builder to concatenate files.
351#
352# Used to append the Python zip archive to the executable.
353#
354###################################################
355
356concat_builder = Builder(action = Action(['cat $SOURCES > $TARGET',
357                                          'chmod +x $TARGET']))
358
359env.Append(BUILDERS = { 'Concat' : concat_builder })
360
361
362# base help text
363help_text = '''
364Usage: scons [scons options] [build options] [target(s)]
365
366'''
367
368# libelf build is shared across all configs in the build root.
369env.SConscript('ext/libelf/SConscript',
370               build_dir = os.path.join(build_root, 'libelf'),
371               exports = 'env')
372
373###################################################
374#
375# Define build environments for selected configurations.
376#
377###################################################
378
379# rename base env
380base_env = env
381
382for build_path in build_paths:
383    print "Building in", build_path
384    # build_dir is the tail component of build path, and is used to
385    # determine the build parameters (e.g., 'ALPHA_SE')
386    (build_root, build_dir) = os.path.split(build_path)
387    # Make a copy of the build-root environment to use for this config.
388    env = base_env.Copy()
389
390    # Set env options according to the build directory config.
391    sticky_opts.files = []
392    # Options for $BUILD_ROOT/$BUILD_DIR are stored in
393    # $BUILD_ROOT/options/$BUILD_DIR so you can nuke
394    # $BUILD_ROOT/$BUILD_DIR without losing your options settings.
395    current_opts_file = os.path.join(build_root, 'options', build_dir)
396    if os.path.isfile(current_opts_file):
397        sticky_opts.files.append(current_opts_file)
398        print "Using saved options file %s" % current_opts_file
399    else:
400        # Build dir-specific options file doesn't exist.
401
402        # Make sure the directory is there so we can create it later
403        opt_dir = os.path.dirname(current_opts_file)
404        if not os.path.isdir(opt_dir):
405            os.mkdir(opt_dir)
406
407        # Get default build options from source tree.  Options are
408        # normally determined by name of $BUILD_DIR, but can be
409        # overriden by 'default=' arg on command line.
410        default_opts_file = os.path.join('build_opts',
411                                         ARGUMENTS.get('default', build_dir))
412        if os.path.isfile(default_opts_file):
413            sticky_opts.files.append(default_opts_file)
414            print "Options file %s not found,\n  using defaults in %s" \
415                  % (current_opts_file, default_opts_file)
416        else:
417            print "Error: cannot find options file %s or %s" \
418                  % (current_opts_file, default_opts_file)
419            Exit(1)
420
421    # Apply current option settings to env
422    sticky_opts.Update(env)
423    nonsticky_opts.Update(env)
424
425    help_text += "Sticky options for %s:\n" % build_dir \
426                 + sticky_opts.GenerateHelpText(env) \
427                 + "\nNon-sticky options for %s:\n" % build_dir \
428                 + nonsticky_opts.GenerateHelpText(env)
429
430    # Process option settings.
431
432    if not have_fenv and env['USE_FENV']:
433        print "Warning: <fenv.h> not available; " \
434              "forcing USE_FENV to False in", build_dir + "."
435        env['USE_FENV'] = False
436
437    if not env['USE_FENV']:
438        print "Warning: No IEEE FP rounding mode control in", build_dir + "."
439        print "         FP results may deviate slightly from other platforms."
440
441    if env['EFENCE']:
442        env.Append(LIBS=['efence'])
443
444    if env['USE_MYSQL']:
445        if not have_mysql:
446            print "Warning: MySQL not available; " \
447                  "forcing USE_MYSQL to False in", build_dir + "."
448            env['USE_MYSQL'] = False
449        else:
450            print "Compiling in", build_dir, "with MySQL support."
451            env.ParseConfig(mysql_config_libs)
452            env.ParseConfig(mysql_config_include)
453
454    # Save sticky option settings back to current options file
455    sticky_opts.Save(current_opts_file, env)
456
457    # Do this after we save setting back, or else we'll tack on an
458    # extra 'qdo' every time we run scons.
459    if env['BATCH']:
460        env['CC']  = env['BATCH_CMD'] + ' ' + env['CC']
461        env['CXX'] = env['BATCH_CMD'] + ' ' + env['CXX']
462
463    if env['USE_SSE2']:
464        env.Append(CCFLAGS='-msse2')
465
466    # The m5/SConscript file sets up the build rules in 'env' according
467    # to the configured options.  It returns a list of environments,
468    # one for each variant build (debug, opt, etc.)
469    envList = SConscript('src/SConscript', build_dir = build_path,
470                         exports = 'env', duplicate = False)
471
472    # Set up the regression tests for each build.
473#    for e in envList:
474#        SConscript('m5-test/SConscript',
475#                   build_dir = os.path.join(build_dir, 'test', e.Label),
476#                   exports = { 'env' : e }, duplicate = False)
477
478Help(help_text)
479
480###################################################
481#
482# Let SCons do its thing.  At this point SCons will use the defined
483# build environments to build the requested targets.
484#
485###################################################
486
487