SConstruct revision 2635:47ee03367e30 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29###################################################
30#
31# SCons top-level build description (SConstruct) file.
32#
33# While in this directory ('m5'), just type 'scons' to build the default
34# configuration (see below), or type 'scons build/<CONFIG>/<binary>'
35# to build some other configuration (e.g., 'build/ALPHA_FS/m5.opt' for
36# the optimized full-system version).
37#
38# You can build M5 in a different directory as long as there is a
39# 'build/<CONFIG>' somewhere along the target path.  The build system
40# expdects that all configs under the same build directory are being
41# built for the same host system.
42#
43# Examples:
44#   These two commands are equivalent.  The '-u' option tells scons to
45#   search up the directory tree for this SConstruct file.
46#   % cd <path-to-src>/m5 ; scons build/ALPHA_FS/m5.debug
47#   % cd <path-to-src>/m5/build/ALPHA_FS; scons -u m5.debug
48#   These two commands are equivalent and demonstrate building in a
49#   directory outside of the source tree.  The '-C' option tells scons
50#   to chdir to the specified directory to find this SConstruct file.
51#   % cd <path-to-src>/m5 ; scons /local/foo/build/ALPHA_FS/m5.debug
52#   % cd /local/foo/build/ALPHA_FS; scons -C <path-to-src>/m5 m5.debug
53#
54# You can use 'scons -H' to print scons options.  If you're in this
55# 'm5' directory (or use -u or -C to tell scons where to find this
56# file), you can use 'scons -h' to print all the M5-specific build
57# options as well.
58#
59###################################################
60
61# Python library imports
62import sys
63import os
64
65# Check for recent-enough Python and SCons versions
66EnsurePythonVersion(2,3)
67EnsureSConsVersion(0,96,91)
68
69# The absolute path to the current directory (where this file lives).
70ROOT = Dir('.').abspath
71
72# Paths to the M5 and external source trees.
73SRCDIR = os.path.join(ROOT, 'src')
74
75# tell python where to find m5 python code
76sys.path.append(os.path.join(ROOT, 'src/python'))
77
78###################################################
79#
80# Figure out which configurations to set up based on the path(s) of
81# the target(s).
82#
83###################################################
84
85# Find default configuration & binary.
86Default(os.environ.get('M5_DEFAULT_BINARY', 'build/ALPHA_SE/m5.debug'))
87
88# Ask SCons which directory it was invoked from.
89launch_dir = GetLaunchDir()
90
91# Make targets relative to invocation directory
92abs_targets = map(lambda x: os.path.normpath(os.path.join(launch_dir, str(x))),
93                  BUILD_TARGETS)
94
95# helper function: find last occurrence of element in list
96def rfind(l, elt, offs = -1):
97    for i in range(len(l)+offs, 0, -1):
98        if l[i] == elt:
99            return i
100    raise ValueError, "element not found"
101
102# Each target must have 'build' in the interior of the path; the
103# directory below this will determine the build parameters.  For
104# example, for target 'foo/bar/build/ALPHA_SE/arch/alpha/blah.do' we
105# recognize that ALPHA_SE specifies the configuration because it
106# follow 'build' in the bulid path.
107
108# Generate a list of the unique build roots and configs that the
109# collected targets reference.
110build_paths = []
111build_roots = []
112for t in abs_targets:
113    path_dirs = t.split('/')
114    try:
115        build_top = rfind(path_dirs, 'build', -2)
116    except:
117        print "Error: no non-leaf 'build' dir found on target path", t
118        Exit(1)
119    build_root = os.path.join('/',*path_dirs[:build_top+1])
120    if build_root not in build_roots:
121        build_roots.append(build_root)
122    build_path = os.path.join('/',*path_dirs[:build_top+2])
123    if build_path not in build_paths:
124        build_paths.append(build_path)
125
126###################################################
127#
128# Set up the default build environment.  This environment is copied
129# and modified according to each selected configuration.
130#
131###################################################
132
133env = Environment(ENV = os.environ,  # inherit user's environment vars
134                  ROOT = ROOT,
135                  SRCDIR = SRCDIR)
136
137env.SConsignFile("sconsign")
138
139# I waffle on this setting... it does avoid a few painful but
140# unnecessary builds, but it also seems to make trivial builds take
141# noticeably longer.
142if False:
143    env.TargetSignatures('content')
144
145# M5_PLY is used by isa_parser.py to find the PLY package.
146env.Append(ENV = { 'M5_PLY' : Dir('ext/ply') })
147
148# Set up default C++ compiler flags
149env.Append(CCFLAGS='-pipe')
150env.Append(CCFLAGS='-fno-strict-aliasing')
151env.Append(CCFLAGS=Split('-Wall -Wno-sign-compare -Werror -Wundef'))
152if sys.platform == 'cygwin':
153    # cygwin has some header file issues...
154    env.Append(CCFLAGS=Split("-Wno-uninitialized"))
155env.Append(CPPPATH=[Dir('ext/dnet')])
156
157# Default libraries
158env.Append(LIBS=['z'])
159
160# Platform-specific configuration
161conf = Configure(env)
162
163# Check for <fenv.h> (C99 FP environment control)
164have_fenv = conf.CheckHeader('fenv.h', '<>')
165if not have_fenv:
166    print "Warning: Header file <fenv.h> not found."
167    print "         This host has no IEEE FP rounding mode control."
168
169# Check for mysql.
170mysql_config = WhereIs('mysql_config')
171have_mysql = mysql_config != None
172
173# Check MySQL version.
174if have_mysql:
175    mysql_version = os.popen(mysql_config + ' --version').read()
176    mysql_version = mysql_version.split('.')
177    mysql_major = int(mysql_version[0])
178    mysql_minor = int(mysql_version[1])
179    # This version check is probably overly conservative, but it deals
180    # with the versions we have installed.
181    if mysql_major < 4 or (mysql_major == 4 and mysql_minor < 1):
182        print "Warning: MySQL v4.1 or newer required."
183        have_mysql = False
184
185# Set up mysql_config commands.
186if have_mysql:
187    mysql_config_include = mysql_config + ' --include'
188    if os.system(mysql_config_include + ' > /dev/null') != 0:
189        # older mysql_config versions don't support --include, use
190        # --cflags instead
191        mysql_config_include = mysql_config + ' --cflags | sed s/\\\'//g'
192    # This seems to work in all versions
193    mysql_config_libs = mysql_config + ' --libs'
194
195env = conf.Finish()
196
197# Define the universe of supported ISAs
198env['ALL_ISA_LIST'] = ['alpha', 'sparc', 'mips']
199
200# Define the universe of supported CPU models
201env['ALL_CPU_LIST'] = ['AtomicSimpleCPU', 'TimingSimpleCPU',
202                       'FastCPU', 'FullCPU', 'AlphaFullCPU']
203
204# Sticky options get saved in the options file so they persist from
205# one invocation to the next (unless overridden, in which case the new
206# value becomes sticky).
207sticky_opts = Options(args=ARGUMENTS)
208sticky_opts.AddOptions(
209    EnumOption('TARGET_ISA', 'Target ISA', 'alpha', env['ALL_ISA_LIST']),
210    BoolOption('FULL_SYSTEM', 'Full-system support', False),
211    # There's a bug in scons 0.96.1 that causes ListOptions with list
212    # values (more than one value) not to be able to be restored from
213    # a saved option file.  If this causes trouble then upgrade to
214    # scons 0.96.90 or later.
215    ListOption('CPU_MODELS', 'CPU models', 'AtomicSimpleCPU,TimingSimpleCPU',
216               env['ALL_CPU_LIST']),
217    BoolOption('ALPHA_TLASER',
218               'Model Alpha TurboLaser platform (vs. Tsunami)', False),
219    BoolOption('NO_FAST_ALLOC', 'Disable fast object allocator', False),
220    BoolOption('EFENCE', 'Link with Electric Fence malloc debugger',
221               False),
222    BoolOption('SS_COMPATIBLE_FP',
223               'Make floating-point results compatible with SimpleScalar',
224               False),
225    BoolOption('USE_SSE2',
226               'Compile for SSE2 (-msse2) to get IEEE FP on x86 hosts',
227               False),
228    BoolOption('STATS_BINNING', 'Bin statistics by CPU mode', have_mysql),
229    BoolOption('USE_MYSQL', 'Use MySQL for stats output', have_mysql),
230    BoolOption('USE_FENV', 'Use <fenv.h> IEEE mode control', have_fenv),
231    ('CC', 'C compiler', os.environ.get('CC', env['CC'])),
232    ('CXX', 'C++ compiler', os.environ.get('CXX', env['CXX'])),
233    BoolOption('BATCH', 'Use batch pool for build and tests', False),
234    ('BATCH_CMD', 'Batch pool submission command name', 'qdo')
235    )
236
237# Non-sticky options only apply to the current build.
238nonsticky_opts = Options(args=ARGUMENTS)
239nonsticky_opts.AddOptions(
240    BoolOption('update_ref', 'Update test reference outputs', False)
241    )
242
243# These options get exported to #defines in config/*.hh (see m5/SConscript).
244env.ExportOptions = ['FULL_SYSTEM', 'ALPHA_TLASER', 'USE_FENV', \
245                     'USE_MYSQL', 'NO_FAST_ALLOC', 'SS_COMPATIBLE_FP', \
246                     'STATS_BINNING']
247
248# Define a handy 'no-op' action
249def no_action(target, source, env):
250    return 0
251
252env.NoAction = Action(no_action, None)
253
254###################################################
255#
256# Define a SCons builder for configuration flag headers.
257#
258###################################################
259
260# This function generates a config header file that #defines the
261# option symbol to the current option setting (0 or 1).  The source
262# operands are the name of the option and a Value node containing the
263# value of the option.
264def build_config_file(target, source, env):
265    (option, value) = [s.get_contents() for s in source]
266    f = file(str(target[0]), 'w')
267    print >> f, '#define', option, value
268    f.close()
269    return None
270
271# Generate the message to be printed when building the config file.
272def build_config_file_string(target, source, env):
273    (option, value) = [s.get_contents() for s in source]
274    return "Defining %s as %s in %s." % (option, value, target[0])
275
276# Combine the two functions into a scons Action object.
277config_action = Action(build_config_file, build_config_file_string)
278
279# The emitter munges the source & target node lists to reflect what
280# we're really doing.
281def config_emitter(target, source, env):
282    # extract option name from Builder arg
283    option = str(target[0])
284    # True target is config header file
285    target = os.path.join('config', option.lower() + '.hh')
286    # Force value to 0/1 even if it's a Python bool
287    val = int(eval(str(env[option])))
288    # Sources are option name & value (packaged in SCons Value nodes)
289    return ([target], [Value(option), Value(val)])
290
291config_builder = Builder(emitter = config_emitter, action = config_action)
292
293env.Append(BUILDERS = { 'ConfigFile' : config_builder })
294
295# base help text
296help_text = '''
297Usage: scons [scons options] [build options] [target(s)]
298
299'''
300
301###################################################
302#
303# Define build environments for selected configurations.
304#
305###################################################
306
307# rename base env
308base_env = env
309
310# Spme things (just libelf currently) are shared across all configs in
311# a "build root".  Need to define how to build these just once for
312# each referenced root.
313build_root_env = {}
314for build_root in build_roots:
315    env = base_env.Copy()
316    env.SConscript('ext/libelf/SConscript',
317                   build_dir = os.path.join(build_root, 'libelf'),
318                   exports = 'env')
319    build_root_env[build_root] = env
320
321for build_path in build_paths:
322    print "Building in", build_path
323    # build_dir is the tail component of build path, and is used to
324    # determine the build parameters (e.g., 'ALPHA_SE')
325    (build_root, build_dir) = os.path.split(build_path)
326    # Make a copy of the build-root environment to use for this config.
327    env = build_root_env[build_root].Copy()
328
329    # Set env options according to the build directory config.
330    sticky_opts.files = []
331    # Options for $BUILD_ROOT/$BUILD_DIR are stored in
332    # $BUILD_ROOT/options/$BUILD_DIR so you can nuke
333    # $BUILD_ROOT/$BUILD_DIR without losing your options settings.
334    current_opts_file = os.path.join(build_root, 'options', build_dir)
335    if os.path.isfile(current_opts_file):
336        sticky_opts.files.append(current_opts_file)
337        print "Using saved options file %s" % current_opts_file
338    else:
339        # Build dir-specific options file doesn't exist.
340
341        # Make sure the directory is there so we can create it later
342        opt_dir = os.path.dirname(current_opts_file)
343        if not os.path.isdir(opt_dir):
344            os.mkdir(opt_dir)
345
346        # Get default build options from source tree.  Options are
347        # normally determined by name of $BUILD_DIR, but can be
348        # overriden by 'default=' arg on command line.
349        default_opts_file = os.path.join('build_opts',
350                                         ARGUMENTS.get('default', build_dir))
351        if os.path.isfile(default_opts_file):
352            sticky_opts.files.append(default_opts_file)
353            print "Options file %s not found,\n  using defaults in %s" \
354                  % (current_opts_file, default_opts_file)
355        else:
356            print "Error: cannot find options file %s or %s" \
357                  % (current_opts_file, default_opts_file)
358            Exit(1)
359
360    # Apply current option settings to env
361    sticky_opts.Update(env)
362    nonsticky_opts.Update(env)
363
364    help_text += "Sticky options for %s:\n" % build_dir \
365                 + sticky_opts.GenerateHelpText(env) \
366                 + "\nNon-sticky options for %s:\n" % build_dir \
367                 + nonsticky_opts.GenerateHelpText(env)
368
369    # Process option settings.
370
371    if not have_fenv and env['USE_FENV']:
372        print "Warning: <fenv.h> not available; " \
373              "forcing USE_FENV to False in", build_dir + "."
374        env['USE_FENV'] = False
375
376    if not env['USE_FENV']:
377        print "Warning: No IEEE FP rounding mode control in", build_dir + "."
378        print "         FP results may deviate slightly from other platforms."
379
380    if env['EFENCE']:
381        env.Append(LIBS=['efence'])
382
383    if env['USE_MYSQL']:
384        if not have_mysql:
385            print "Warning: MySQL not available; " \
386                  "forcing USE_MYSQL to False in", build_dir + "."
387            env['USE_MYSQL'] = False
388        else:
389            print "Compiling in", build_dir, "with MySQL support."
390            env.ParseConfig(mysql_config_libs)
391            env.ParseConfig(mysql_config_include)
392
393    # Save sticky option settings back to current options file
394    sticky_opts.Save(current_opts_file, env)
395
396    # Do this after we save setting back, or else we'll tack on an
397    # extra 'qdo' every time we run scons.
398    if env['BATCH']:
399        env['CC']  = env['BATCH_CMD'] + ' ' + env['CC']
400        env['CXX'] = env['BATCH_CMD'] + ' ' + env['CXX']
401
402    if env['USE_SSE2']:
403        env.Append(CCFLAGS='-msse2')
404
405    # The m5/SConscript file sets up the build rules in 'env' according
406    # to the configured options.  It returns a list of environments,
407    # one for each variant build (debug, opt, etc.)
408    envList = SConscript('src/SConscript', build_dir = build_path,
409                         exports = 'env', duplicate = False)
410
411    # Set up the regression tests for each build.
412#    for e in envList:
413#        SConscript('m5-test/SConscript',
414#                   build_dir = os.path.join(build_dir, 'test', e.Label),
415#                   exports = { 'env' : e }, duplicate = False)
416
417Help(help_text)
418
419###################################################
420#
421# Let SCons do its thing.  At this point SCons will use the defined
422# build environments to build the requested targets.
423#
424###################################################
425
426