SConstruct revision 1862 
1# -*- mode:python -*-
2
3# Copyright (c) 2004-2005 The Regents of The University of Michigan
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions are
8# met: redistributions of source code must retain the above copyright
9# notice, this list of conditions and the following disclaimer;
10# redistributions in binary form must reproduce the above copyright
11# notice, this list of conditions and the following disclaimer in the
12# documentation and/or other materials provided with the distribution;
13# neither the name of the copyright holders nor the names of its
14# contributors may be used to endorse or promote products derived from
15# this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
18# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
19# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
20# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
21# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
22# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
23# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
27# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29###################################################
30#
31# SCons top-level build description (SConstruct) file.
32#
33# To build M5, you need a directory with three things:
34# 1. A copy of this file (named SConstruct).
35# 2. A link named 'm5' to the top of the M5 simulator source tree.
36# 3. A link named 'ext' to the top of the M5 external source tree.
37#
38# Then type 'scons' to build the default configuration (see below), or
39# 'scons <CONFIG>/<binary>' to build some other configuration (e.g.,
40# 'ALPHA_FS/m5.opt' for the optimized full-system version).
41#
42###################################################
43
44# Python library imports
45import sys
46import os
47
48# Check for recent-enough Python and SCons versions
49EnsurePythonVersion(2,3)
50EnsureSConsVersion(0,96)
51
52# The absolute path to the current directory (where this file lives).
53ROOT = Dir('.').abspath
54
55# Paths to the M5 and external source trees (local symlinks).
56SRCDIR = os.path.join(ROOT, 'm5')
57EXT_SRCDIR = os.path.join(ROOT, 'ext')
58
59# Check for 'm5' and 'ext' links, die if they don't exist.
60if not os.path.isdir(SRCDIR):
61    print "Error: '%s' must be a link to the M5 source tree." % SRCDIR
62    Exit(1)
63
64if not os.path.isdir('ext'):
65    print "Error: '%s' must be a link to the M5 external source tree." \
66          % EXT_SRCDIR
67    Exit(1)
68
69# tell python where to find m5 python code
70sys.path.append(os.path.join(SRCDIR, 'python'))
71
72###################################################
73#
74# Figure out which configurations to set up.
75#
76#
77# It's prohibitive to do all the combinations of base configurations
78# and options, so we have to infer which ones the user wants.
79#
80# 1. If there are command-line targets, the configuration(s) are inferred
81#    from the directories of those targets.  If scons was invoked from a
82#    subdirectory (using 'scons -u'), those targets have to be
83#    interpreted relative to that subdirectory.
84#
85# 2. If there are no command-line targets, and scons was invoked from a
86#    subdirectory (using 'scons -u'), the configuration is inferred from
87#    the name of the subdirectory.
88#
89# 3. If there are no command-line targets and scons was invoked from
90#    the root build directory, a default configuration is used.  The
91#    built-in default is ALPHA_SE, but this can be overridden by setting the
92#    M5_DEFAULT_CONFIG shell environment veriable.
93#
94# In cases 2 & 3, the specific file target defaults to 'm5.debug', but
95# this can be overridden by setting the M5_DEFAULT_BINARY shell
96# environment veriable.
97#
98###################################################
99
100# Find default configuration & binary.
101default_config = os.environ.get('M5_DEFAULT_CONFIG', 'ALPHA_SE')
102default_binary = os.environ.get('M5_DEFAULT_BINARY', 'm5.debug')
103
104# Ask SCons which directory it was invoked from.  If you invoke SCons
105# from a subdirectory you must use the '-u' flag.
106launch_dir = GetLaunchDir()
107
108# Build a list 'my_targets' of all the targets relative to ROOT.
109if launch_dir == ROOT:
110    # invoked from root build dir
111    if len(COMMAND_LINE_TARGETS) != 0:
112        # easy: use specified targets as is
113        my_targets = COMMAND_LINE_TARGETS
114    else:
115        # default target (ALPHA_SE/m5.debug, unless overridden)
116        target = os.path.join(default_config, default_binary)
117        my_targets = [target]
118        Default(target)
119else:
120    # invoked from subdirectory
121    if not launch_dir.startswith(ROOT):
122        print "Error: launch dir (%s) not a subdirectory of ROOT (%s)!" \
123              (launch_dir, ROOT)
124        Exit(1)
125    # make launch_dir relative to ROOT (strip ROOT plus slash off front)
126    launch_dir = launch_dir[len(ROOT)+1:]
127    if len(COMMAND_LINE_TARGETS) != 0:
128        # make specified targets relative to ROOT
129        my_targets = map(lambda x: os.path.join(launch_dir, x),
130                         COMMAND_LINE_TARGETS)
131    else:
132        # build default binary (m5.debug, unless overridden) using the
133        # config inferred by the invocation directory (the first
134        # subdirectory after ROOT)
135        target = os.path.join(launch_dir.split('/')[0], default_binary)
136        my_targets = [target]
137        Default(target)
138
139# Normalize target paths (gets rid of '..' in the middle, etc.)
140my_targets = map(os.path.normpath, my_targets)
141
142# Generate a list of the unique configs that the collected targets reference.
143build_dirs = []
144for t in my_targets:
145    dir = t.split('/')[0]
146    if dir not in build_dirs:
147        build_dirs.append(dir)
148
149###################################################
150#
151# Set up the default build environment.  This environment is copied
152# and modified according to each selected configuration.
153#
154###################################################
155
156env = Environment(ENV = os.environ,  # inherit user's environment vars
157                  ROOT = ROOT,
158                  SRCDIR = SRCDIR,
159                  EXT_SRCDIR = EXT_SRCDIR)
160
161env.SConsignFile("sconsign")
162
163if os.environ.has_key('CC'):
164    env.Replace(CC=os.environ['CC'])
165
166if os.environ.has_key('CXX'):
167    env.Replace(CXX=os.environ['CXX'])
168
169# M5_EXT is used by isa_parser.py to find the PLY package.
170env.Append(ENV = { 'M5_EXT' : EXT_SRCDIR })
171
172# Set up default C++ compiler flags
173env.Append(CCFLAGS='-pipe')
174env.Append(CCFLAGS='-fno-strict-aliasing')
175env.Append(CCFLAGS=Split('-Wall -Wno-sign-compare -Werror -Wundef'))
176if sys.platform == 'cygwin':
177    # cygwin has some header file issues...
178    env.Append(CCFLAGS=Split("-Wno-uninitialized"))
179env.Append(CPPPATH=[os.path.join(EXT_SRCDIR + '/dnet')])
180
181# Default libraries
182env.Append(LIBS=['z'])
183
184# Platform-specific configuration
185conf = Configure(env)
186
187# Check for <fenv.h> (C99 FP environment control)
188have_fenv = conf.CheckHeader('fenv.h', '<>')
189if not have_fenv:
190    print "Warning: Header file <fenv.h> not found."
191    print "         This host has no IEEE FP rounding mode control."
192
193# Check for mysql.
194mysql_config = WhereIs('mysql_config')
195have_mysql = mysql_config != None
196
197# Check MySQL version.
198if have_mysql:
199    mysql_version = os.popen(mysql_config + ' --version').read()
200    mysql_version = mysql_version.split('.')
201    mysql_major = int(mysql_version[0])
202    mysql_minor = int(mysql_version[1])
203    # This version check is probably overly conservative, but it deals
204    # with the versions we have installed.
205    if mysql_major < 3 or \
206           mysql_major == 3 and mysql_minor < 23 or \
207           mysql_major == 4 and mysql_minor < 1:
208        print "Warning: MySQL v3.23 or v4.1 or newer required."
209        have_mysql = False
210
211# Set up mysql_config commands.
212if have_mysql:
213    mysql_config_include = mysql_config + ' --include'
214    if os.system(mysql_config_include + ' > /dev/null') != 0:
215        # older mysql_config versions don't support --include, use
216        # --cflags instead
217        mysql_config_include = mysql_config + ' --cflags | sed s/\\\'//g'
218    # This seems to work in all versions
219    mysql_config_libs = mysql_config + ' --libs'
220
221env = conf.Finish()
222
223# The source operand is a Value node containing the value of the option.
224def build_config_file(target, source, env, option):
225    f = file(str(target[0]), 'w')
226    print >> f, '#define', option, source[0]
227    f.close()
228    return None
229
230def config_builder(env, option):
231    target = os.path.join('config', option.lower() + '.hh')
232    source = Value(env[option])
233    def my_build_config_file(target, source, env):
234        build_config_file(target, source, env, option)
235    env.Command(target, source, my_build_config_file)
236
237env.Append(BUILDERS = { 'ConfigFile' : config_builder })
238
239# libelf build is described in its own SConscript file.
240# SConscript-global is the build in build/libelf shared among all
241# configs.
242env.SConscript('m5/libelf/SConscript-global', exports = 'env')
243
244###################################################
245#
246# Define build environments for selected configurations.
247#
248###################################################
249
250# rename base env
251base_env = env
252
253for build_dir in build_dirs:
254    # Make a copy of the default environment to use for this config.
255    env = base_env.Copy()
256    # Set env according to the build directory config.
257    options_file = os.path.join('build_options', build_dir)
258    if not os.path.isfile(options_file):
259        print "Options file %s not found, using defaults." % options_file
260    opts = Options(options_file, ARGUMENTS)
261    opts.AddOptions(
262        EnumOption('TARGET_ISA', 'Target ISA', 'alpha', ('alpha')),
263        BoolOption('FULL_SYSTEM', 'Full-system support', False),
264        BoolOption('ALPHA_TLASER',
265                   'Model Alpha TurboLaser platform (vs. Tsunami)', False),
266        BoolOption('NO_FAST_ALLOC', 'Disable fast object allocator', False),
267        BoolOption('EFENCE', 'Link with Electric Fence malloc debugger',
268                   False),
269        BoolOption('SS_COMPATIBLE_FP',
270                   'Make floating-point results compatible with SimpleScalar',
271                   False),
272        BoolOption('STATS_BINNING', 'Bin statistics by CPU mode', have_mysql),
273        BoolOption('USE_MYSQL', 'Use MySQL for stats output', have_mysql),
274        BoolOption('USE_FENV', 'Use <fenv.h> IEEE mode control', have_fenv)
275        )
276
277    opts.Update(env)
278    opts.Save(options_file, env)
279
280    env.ExportOptions = ['FULL_SYSTEM', 'ALPHA_TLASER', 'USE_FENV', \
281                         'USE_MYSQL', 'NO_FAST_ALLOC', 'SS_COMPATIBLE_FP', \
282                         'STATS_BINNING']
283
284    # Process option settings.
285
286    if not have_fenv and env['USE_FENV']:
287        print "Warning: <fenv.h> not available; " \
288              "forcing USE_FENV to False in", build_dir + "."
289        env['USE_FENV'] = False
290
291    if not env['USE_FENV']:
292        print "Warning: No IEEE FP rounding mode control in", build_dir + "."
293        print "         FP results may deviate slightly", \
294              "and some regression tests may fail."
295
296    if env['EFENCE']:
297        env.Append(LIBS=['efence'])
298
299    if env['USE_MYSQL']:
300        if not have_mysql:
301            print "Warning: MySQL not available; " \
302                  "forcing USE_MYSQL to False in", build_dir + "."
303            env['USE_MYSQL'] = False
304        else:
305            print "Compiling in", build_dir, "with MySQL support."
306            env.ParseConfig(mysql_config_libs)
307            env.ParseConfig(mysql_config_include)
308    
309    # The m5/SConscript file sets up the build rules in 'env' according
310    # to the configured options.
311    SConscript('m5/SConscript', build_dir = build_dir, exports = 'env',
312               duplicate=0)
313
314###################################################
315#
316# Let SCons do its thing.  At this point SCons will use the defined
317# build environments to build the requested targets.
318#
319###################################################
320
321